(Visual Basic 6.0) Use a Custom Set of Trusted Root Certificates

Demonstrates how to build a set of trusted root certificates to be used globally by all Chilkat classes.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim trustedRoots As New ChilkatTrustedRoots

'  Indicate that we will NOT trust any pre-installed certificates on the system.
trustedRoots.TrustSystemCaRoots = 0

' Thawte is a certificate authority that provides a .zip download of their
' root CA certificates:  https://www.thawte.com/roots/index.html
' The direct download link is: https://www.verisign.com/support/thawte-roots.zip
' Note: The above URLs are valid at the time of writing this example (29-May-2015).

' Assuming the .zip has already been downloaded, open it and load each .pem file into
' our trusted roots object.
Dim zip As New ChilkatZip

' Open a .zip containing PEM files, among other things..
Dim success As Long
success = zip.OpenZip("qa_data/certs/thawte-roots.zip")
If (success <> 1) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

Dim entry As ChilkatZipEntry
Set entry = zip.FirstMatchingEntry("*.pem")
If (zip.LastMethodSuccess <> 1) Then
    Debug.Print "No entries matched."
    Exit Sub
End If

Dim nextEntry As ChilkatZipEntry
Dim pemStr As String

Dim cert As New ChilkatCert

Dim bHasMoreEntries As Long
bHasMoreEntries = 1
Do While (bHasMoreEntries = 1)

    Debug.Print "Entry: " & entry.FileName

    ' Get the PEM of the CA cert:
    pemStr = entry.UnzipToString(0,"utf-8")

    ' Load it into a certificate object:
    success = cert.LoadPem(pemStr)
    If (success <> 1) Then
        Debug.Print cert.LastErrorText
    End If

    ' Add it to the trusted roots.
    success = trustedRoots.AddCert(cert)

    ' The NextMatchingEntry method was added in v9.5.0.50
    Set nextEntry = entry.NextMatchingEntry("*.pem")
    bHasMoreEntries = entry.LastMethodSuccess

    Set entry = nextEntry
Loop

'  Activate the trusted roots globally for all Chilkat objects.
'  This call really shouldn't fail, so we're not checking the return value.
success = trustedRoots.Activate()