(Visual Basic 6.0) Adding Cookies to an HTTP Request

Demonstrates how to add one or more cookies to an HTTP request.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' The Cookie header field has this format:
' Cookie: name1=value1 [; name2=value2] ...

' Build an HTTP POST request:
Dim req As New ChilkatHttpRequest
req.SetFromUrl "http://www.chilkatsoft.com/echoPost.asp"
req.HttpVerb = "POST"

req.AddParam "param1","value1"
req.AddParam "param2","value2"

' To add cookies to any HTTP request sent by a Chilkat HTTP method
' that uses an HTTP request object, add the cookies to the
' request object by calling AddHeader.  

' Add two cookies:
req.AddHeader "Cookie","user=""mary""; city=""Chicago"""

' Send the HTTP POST.  
' (The cookies are sent as part of the HTTP header.)

Dim resp As ChilkatHttpResponse
Dim domain As String
domain = "www.chilkatsoft.com"
Dim port As Long
port = 80
Dim ssl As Long
ssl = 0
Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Display the HTML body of the response.
If (resp.StatusCode = 200) Then
    ' Show the last HTTP request header sent, which should include
    ' our cookies...
    Debug.Print http.LastHeader
Else
    Debug.Print "HTTP Response Status = " & resp.StatusCode
End If

Debug.Print "---------------------"

' Some Chilkat HTTP methods do not use an HTTP request object. 
' For these methods, such as for QuickGetStr, cookies (or any HTTP request header) 
' are added by calling SetRequestHeader.  
http.SetRequestHeader "Cookie","user=""mary""; city=""Chicago"""

Dim html As String
html = http.QuickGetStr("http://www.w3.org/")
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
Else
    ' Show the last HTTP request header sent, which should include
    ' our cookies...
    Debug.Print http.LastHeader
End If