(Visual Basic 6.0) HttpPostJson2Async Example

Demonstrates use of the HttpPostJson2Async method.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code

'  See PostJson2 Example for the synchronous equivalent of this example.

Dim http As New ChilkatHttp

Dim success As Long

'  Sends a POST equivalent to the following CURL command:

'  curl -X POST https://sandbox.plaid.com/institutions/get \
'    -H 'content-type: application/json' \
'    -d '{
'      "client_id": String,
'      "secret":String,
'      "count": Number,
'      "offset": Number
'    }'

'  Suppress some default headers that would automatically added..
http.AcceptCharset = ""
http.UserAgent = ""
http.AcceptLanguage = ""
http.AllowGzip = 0

Dim jsonBody As String
jsonBody = "{""client_id"": ""PLAID_CLIENT_ID"", ""secret"":""PLAID_SECRET"", ""count"": 10, ""offset"": 0}"
Dim task As ChilkatTask
Set task = http.PostJson2Async("https://sandbox.plaid.com/institutions/get","application/json",jsonBody)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

'  Start the background task.
success = task.Run()
If (Not success) Then
    Debug.Print task.LastErrorText

    Exit Sub
End If

'  The application is now free to do anything else
'  while the HTTP POST is in progress

'  For this example, we'll simply sleep and periodically
'  check to see if the HTTP POST is finished.
Do While task.Finished <> 1
    '  Sleep 100 ms.
    task.SleepMs 100
Loop

'  When we get here, the task is either finished successfully or not, or was canceled/aborted.

'  If the task was "canceled", it was canceled prior to actually starting.  This could
'  happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
'  background thread pool scheduler.

'  If the task was "aborted", it indicates that it was canceled while running in a background thread.
'  The ResultErrorText will likely indicate that the task was aborted.

'  If the task "completed", then it ran to completion, but the actual success/failure of the method
'  is determined by getting the result of the underlying method call.
'  A task status of 7 indicates completion.
If (task.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task status: " & task.Status

    Exit Sub
End If

'  When called synchronously, the PostJson2 method returns an HTTP response object,
'  unless the method failed and there was no response to be had.
'  Check to see if PostJson2 method failed (and thus there is no response object).
If (task.TaskSuccess = 0) Then
    Debug.Print "The underlying task failed, and there is no HTTP response object."
    Debug.Print "The LastErrorText for the underlying method call is:"
    Debug.Print task.ResultErrorText

    Exit Sub
End If

'  To get the HTTP response object, create a new instance and load it with the result from the task.
Dim resp As New ChilkatHttpResponse
success = resp.LoadTaskResult(task)

Dim statusCode As Long
statusCode = resp.StatusCode
Debug.Print "Response status code = " & statusCode

'  Examine the JSON response..
Dim json As New ChilkatJsonObject
success = json.Load(resp.BodyStr)
json.EmitCompact = 0
Debug.Print "JSON Response Body:"
Debug.Print json.Emit()