Visual Basic 6.0

Refresh HMRC OAuth2 Access Token

See more OAuth2 Examples

Demonstrates how to refresh an HMRC access token. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See Get HMRC Access Token 
' for sample code showing how to obtain a HMRC access token for desktop apps.

' It is assumed we previously obtained an OAuth2 access token for HMRC.

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/hmrc.json")
If (success <> 1) Then
    Debug.Print "Failed to load hmrc.json"
    Exit Sub
End If

' The access token JSON looks something like this:

' {
'   "token_type": "Bearer",
'   "scope": "user_impersonation",
'   "expires_in": "3599",
'   "ext_expires_in": "0",
'   "expires_on": "1524783438",
'   "not_before": "1524779538",
'   "resource": "https://mydomain.api.crm.dynamics.com",
'   "access_token": "...",
'   "refresh_token": "...",
'   "id_token": "..."
' }

Dim oauth2 As New ChilkatOAuth2

oauth2.TokenEndpoint = "https://test-api.service.hmrc.gov.uk/oauth/token"

' Replace these with actual values.
oauth2.ClientId = "HMRC-CLIENT-ID"
oauth2.ClientSecret = "HMRC-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

' Load the access token response into the json object 
success = jsonToken.Load(oauth2.AccessTokenResponse)

' If an "expires_on" member does not exist, then add the JSON member by
' getting the current system date/time and adding the "expires_in" seconds.
' This way we'll know when the token expires.
If (jsonToken.HasMember("expires_on") = 0) Then
    Dim dtExpire As New CkDateTime
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(jsonToken.IntOf("expires_in"))
    success = jsonToken.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(0))
End If

' Save the new JSON access token response to a file.
' The access + refresh tokens contained in this JSON will be needed for the next refresh.
Dim sbJson As New ChilkatStringBuilder
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/hmrc.json","utf-8",0)

Debug.Print "OAuth2 authorization granted!"
Debug.Print "New Access Token = " & oauth2.AccessToken