(Visual Basic 6.0) Create a Hash Signature for Value Added Tax Audit SOAP Message for Angola

Demonstrates how to create a hash signature that is required in Value Added Tax Audit Files in Angola, Africa.

It is the following two instructions that should be used to create a hash value to be put into a <hash></hash> field in SOAP XML file containing the tax data for the VAT authorities:

openssl dgst -shal -sign private.pem -outRegisto1.shal Registo1.txt

then

openssl enc -base64 - in Registo1.shal -out Registo1.b64 -A

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim pkey As New PrivateKey

' Load the private key from an PEM file.
' Provide the password in the 2nd argument.
' If no password is needed, just pass an empty string.
Dim success As Long
success = pkey.LoadAnyFormatFile("qa_data/rsa/rsaPrivKey_secret.pem","secret")
If (success <> 1) Then
    Debug.Print pkey.LastErrorText
    Exit Sub
End If

' Assuming this is an RSA private key..
Dim rsa As New ChilkatRsa

' Import the private key into the RSA object:
success = rsa.ImportPrivateKeyObj(pkey)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' OpenSSL uses big-endian.
rsa.LittleEndian = 0

' SHA1 hash and sign, and return base64.
rsa.EncodingMode = "base64"
Dim b64sig As String
b64sig = rsa.SignStringENC("2018-05-18,2018-05-18T11:22:19;FAC 001/18;53.00;","sha1")
Debug.Print b64sig

' The signature is equal in size to your private key.  For example, if you have a 1024-bit RSA key,
' then 1024 bits = 128 bytes.   When 128 bytes is base64 encoded, the result is a string approximately
' 4/3rds the size of the original.  128 * 4 / 3 = (approximately) 172 bytes.

' If your RSA key is 2048-bits, then your signature will be twice as long.