(Visual Basic 6.0) Validate a Google ID Token

Demonstrates how to verify the signature of a Google id token.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' First get the public key we'll be needing..
Dim jwkStr As String
jwkStr = http.QuickGetStr("https://www.googleapis.com/oauth2/v3/certs")
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' We have the following:

'     {
'       "keys": [
' 	{
' 	  "kid": "e8732db06287515556213b80acbcfd08cfb302a9",
' 	  "n": "4RIrO30287Wsq3gqXCMkUYMVAeI3H8...w2mbMNEBQ",
' 	  "kty": "RSA",
' 	  "e": "AQAB",
' 	  "alg": "RS256",
' 	  "use": "sig"
' 	},
' 	{
' 	  "kid": "8462a71da4f6d611fc0fecf0fc4ba9c37d65e6cd",
' 	  "e": "AQAB",
' 	  "n": "xT_ngLZNmT5GBtJZeTB...Ft4gK0eoFi0d3l8bcw",
' 	  "alg": "RS256",
' 	  "use": "sig",
' 	  "kty": "RSA"
' 	}
'       ]
'     }

Dim json As New ChilkatJsonObject
Dim success As Long
success = json.Load(jwkStr)

' -------------------------------------------------

' Load the following..

'  {
'   "access_token": "ya29.a0...0f",
'   "expires_in": 3599,
'   "scope": "openid https://www.googleapis.com/auth/userinfo.email",
'   "token_type": "Bearer",
'   "id_token": "eyJhb...o5nQ"
' }

Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/google_sample_id_token.json")
If (success = 0) Then
    Debug.Print "Failed to load the JSON file..."
    Exit Sub
End If

' Get the id_token;
Dim sbIdToken As New ChilkatStringBuilder
success = sbIdToken.Append(jsonToken.StringOf("id_token"))

' Get the signature in base64url format.
' The header + payload remains in sbIdToken.
Dim sig_b64Url As String
sig_b64Url = sbIdToken.GetAfterFinal(".",1)
Dim headerPlusPayload As String
headerPlusPayload = sbIdToken.GetAsString()

Debug.Print sig_b64Url
Debug.Print headerPlusPayload

' ---------------------------------------------

' Try validating with each cert's public key.
' Hopefully one will be the key that verifies.

Dim rsa As New ChilkatRsa
rsa.EncodingMode = "base64url"

Dim numKeys As Long
numKeys = json.SizeOfArray("keys")
Dim i As Long
i = 0
Do While i < numKeys
    json.I = i
    Dim jsonKey As ChilkatJsonObject
    Set jsonKey = json.ObjectOf("keys[i]")
    Dim pubKey As New PublicKey
    success = pubKey.LoadFromString(jsonKey.Emit())
    If (success = 0) Then
        Debug.Print pubKey.LastErrorText
        Exit Sub
    End If

    Debug.Print i
    Debug.Print pubKey.GetPem(1)

    success = rsa.ImportPublicKeyObj(pubKey)

    Dim bVerified As Long
    bVerified = rsa.VerifyStringENC(headerPlusPayload,"sha256",sig_b64Url)
    Debug.Print "bVerified = " & bVerified

    i = i + 1
Loop

' The output is:

' 0
' -----BEGIN RSA PUBLIC KEY-----
' MIIBCgKCAQEA4RIrO30287Wsq3gqXCMkUYMVAeI3H8LVE6IXR1krdFeGnZLiGUPw
' cbkeVpXf3lmJdsStOg+jijces2DZCfPyIBiQuLYfxxmAZE6ErJ0QJFg1stwli2Pz
' 9ncYhFoqi8pXr7kEzEJBTzX4thuw56ydbGsshSEznPXoerCJOc7UI2+n0wFCWQ4Y
' LHbh/PrWt4vdadyUUUW/QpQHXQLdD8q/Qwqdj0O9zlJE7R6Elw2E9EqnHyIGu1hm
' LxhqrTru1M18SUhONYbVskV/BCEdVKs//X96849HorWQDCAgVMWfGsdMVq55FAdJ
' 680N5UmQDRynIZ4+PeNGN4S9iw2mbMNEBQIDAQAB
' -----END RSA PUBLIC KEY-----
' 
' bVerified = True
' 1
' -----BEGIN RSA PUBLIC KEY-----
' MIIBCgKCAQEAxT/ngLZNmT5GBdkLtJZjNeTB+8B5yWgrq/e5eMZ1hrZhcmLK+dSn
' IkpOPV8/OekV67EnQ7I4II2rcNJnHGrGKZziXO3XN2gtUHE+mBJC99oULSbX/QwB
' Kz7gC/IBPq9EuxTt6Oq6fPkVQ9DbRIgWJSEGBF/KRaNl3kyAlIZfpY7XgHyJTTv8
' E7yAcYKPR+36gzdl+ps0sDLKzUuAtZNq8llK0u80z6AtAUIYwWdkEhM9upy6keKI
' TasIxcsO7M6kZPINUSbh6t5VAm8FuqRmxpgg+9c9/GQSGd89InVypoVzWLQ+wOGg
' 5G4H6JqIgtj0TRFt4gK0eoFi2U0d3l8bcwIDAQAB
' -----END RSA PUBLIC KEY-----
' 
' bVerified = False