(Visual Basic 6.0) Google Drive Insert Permission

This example demonstrates how to insert a permission for a file (see https://developers.google.com/drive/v2/reference/permissions/insert)

The impetus for creating this example was a need to be able to view files uploaded using a service account key in the Google Drive web interface. When using a service account access token, the files your application will see are those for the service account, and not the files for your main account. For example, the Google Account I use for testing has a username of "support@chilkatcloud.com". (Don't send email to support@chilkatcloud.com, it's just use for testing and not interactively read.) I use "support@chilkatcloud.com" when I log into Google interactively to view files in Google Drive at https://drive.google.com/drive/my-drive.

The files I upload to Google Drive using a service account key won't be visible in the browser UI. To make them visible, you need to insert a permission for the file so that the main user account, which in this case is "support@chilkatcloud.com", is a reader. After the permission is inserted, the file will be visible under "Shared with me" -- as if another Google Drive account shared the file with you.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim success As Long
success = 1

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Drive scope.

Dim gAuth As New ChilkatAuthGoogle
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

Dim rest As New ChilkatRest

' Connect using TLS.
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

success = rest.AddHeader("Content-Type","application/json; charset=UTF-8")

Dim json As New ChilkatJsonObject
success = json.AppendString("role","reader")
success = json.AppendString("type","user")
success = json.AppendString("value","support@chilkatcloud.com")

' A note from a Chilkat customer:
' 
'   My coding attempt was frustrated because I tried a role of "owner".
'   Even when providing the extra parameter of ...?transferOwnership=true
'   that approach fails (400, Bad Request).
' 

' This example is inserting a permission for the file whose fileId is "0By-hrxCCDzSQUGxJY0hzNUFpNmc".
Dim jsonResponse As String
jsonResponse = rest.FullRequestString("POST","/drive/v2/files/0By-hrxCCDzSQUGxJY0hzNUFpNmc/permissions",json.Emit())
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print "response status code = " & rest.ResponseStatusCode
    Debug.Print "response status text = " & rest.ResponseStatusText
    Debug.Print "response header: " & rest.ResponseHeader
    Debug.Print "response JSON: " & jsonResponse
    Exit Sub
End If

' Show the JSON response.
success = json.Load(jsonResponse)

' Show the full JSON response.
json.EmitCompact = 0
Debug.Print json.Emit()

Debug.Print "Success."