(Visual Basic 6.0) Send GMail with BCC Recipients using REST API

See more GMail REST API Examples

Demonstrates how to send an email with BCC recipients using the GMail REST API.

Note: This example requires Chilkat v9.5.0.91 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

' Use the Chilkat Email API to create or load an email.
Dim email As New ChilkatEmail

' The From name/address don't need to be specified. 
' GMail will automatically use your Gmail address if the following 2 lines are omitted.
email.FromName = "My Name"
email.FromAddress = "my_account_name@gmail.com"

success = email.AddTo("John Smith","somebody@somewhere.com")
' To add more recipients, make additional calls to AddTo or AddCC, one per recipient...

' -----------------------------------------------------------------------------------------
' This section of this example demonstrates how to add BCC recipients.
' 
' Technically, an email should never contain a "Bcc" MIME header because it would
' effectively nullify the purpose of BCC -- which means "Blind Carbon Copy".
' Email recipients should not be able to see the BCC recipients.
' Chilkat never adds a "Bcc" header field.
' However.. in this case, the GMail REST server will look for the Bcc header field,
' and will include those email addresses when sending, and also removes the Bcc header
' from the email that is sent.
' 
' Starting in Chilkat v9.5.0.91, we can tell the email object to add the Bcc header
' using the "UseBccHeader" UncommonOptions.  For example:
email.UncommonOptions = "UseBccHeader"
success = email.AddBcc("Joe","joe@example.com")
success = email.AddBcc("Dave","dave@example.com")
' ...
' -----------------------------------------------------------------------------------------

email.Subject = "This is a test GMail email created using Chilkat."
email.Charset = "utf-8"
success = email.AddPlainTextAlternativeBody("This is a test")

' Create an HTML email body with an embedded image.
Dim cid As String
cid = email.AddRelatedFile("qa_data/jpg/starfish.jpg")
Dim sbHtml As New ChilkatStringBuilder
success = sbHtml.Append("<html><body>This is a <b>test</b><br><img src=""cid:STARFISH_CID""/></body></html>")
Dim numReplacements As Long
numReplacements = sbHtml.Replace("STARFISH_CID",cid)

success = email.AddHtmlAlternativeBody(sbHtml.GetAsString())

' OK.. we now have an HTML email with an embedded JPG image
' We'll need to get the full MIME of the email encoded to a base64url string.
Dim sbMime As New ChilkatStringBuilder
success = email.GetMimeSb(sbMime)
success = sbMime.Encode("base64url","utf-8")

' The body of the HTTP request will be JSON..
Dim json As New ChilkatJsonObject
success = json.UpdateSb("raw",sbMime)

' Send the email...
Dim http As New ChilkatHttp
http.AuthToken = "GMAIL-ACCESS-TOKEN"

Dim url As String
url = "https://www.googleapis.com/gmail/v1/users/me/messages/send"
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' A status code of 200 indicates success.
Debug.Print "Response status code: " & resp.StatusCode
Debug.Print "Response body:"
Debug.Print resp.BodyStr

' The response body contains JSON.
' Use the online tool at Generate JSON Parsing Code
' to generate JSON parsing code.

' A sample successful JSON response:

' {
'  "id": "166f0d4ac39e50bf",
'  "threadId": "166f0d4ac39e50bf",
'  "labelIds": [
'   "SENT"
'  ]
' }