(Visual Basic 6.0) Create a New GMail Label

Demonstrates how to create a new GMail label.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

Dim http As New ChilkatHttp
http.AuthToken = "GMAIL-ACCESS-TOKEN"

Dim userId As String
userId = "me"
success = http.SetUrlVar("userId",userId)

' Create the JSON to be sent in the HTTP request body.
' The name of the new label is "questions".
Dim json As New ChilkatJsonObject
success = json.UpdateString("name","questions")
success = json.UpdateString("labelListVisibility","labelShow")
success = json.UpdateString("messageListVisibility","show")

json.EmitCompact = 0
Debug.Print json.Emit()

' The JSON contains this:
' {
'   "name": "questions",
'   "labelListVisibility": "labelShow",
'   "messageListVisibility": "show"
' }

Dim url As String
url = "https://www.googleapis.com/gmail/v1/users/{$userId}/labels"
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson3(url,"application/json",json)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "status = " & resp.StatusCode

' A 200 response status indicate success.
If (resp.StatusCode <> 200) Then
    Debug.Print resp.BodyStr
    Debug.Print "Failed."

    Exit Sub
End If

' A successful repsonse contains JSON that looks like this:

' {
'  "id": "Label_43",
'  "name": "questions",
'  "messageListVisibility": "show",
'  "labelListVisibility": "labelShow"
' }

Debug.Print "response body:"
Debug.Print resp.BodyStr

Debug.Print "GMail label created!"