Visual Basic 6.0

Glacier Initiate Archive Retrieval Job

See more Amazon Glacier Examples

Demonstrates how to initiate an archive retrieval job to download an archive.

Note: This example requires Chilkat v9.5.0.78 or greater.

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim rest As New ChilkatRest

' Connect to the Amazon AWS REST server in the desired region.
Dim bTls As Long
bTls = 1
Dim port As Long
port = 443
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("glacier.us-west-2.amazonaws.com",port,bTls,bAutoReconnect)

' Provide AWS credentials.
Dim authAws As New ChilkatAuthAws
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "glacier"
authAws.Region = "us-west-2"

success = rest.SetAuthAws(authAws)

' --------------------------------------------------------------------------
' Note: The above REST connection and setup of the AWS credentials
' can be done once.  After connecting, any number of REST calls can be made.
' The "auto reconnect" property passed to rest.Connect indicates that if
' the connection is lost, a REST method call will automatically reconnect
' if needed.
' --------------------------------------------------------------------------

' 
' For more information, see Glacier Initiate Job Post Reference Documentation
' 
success = rest.AddHeader("x-amz-glacier-version","2012-06-01")

' The body of our request will contain this JSON:
' {
'   "Type": "archive-retrieval",
'   "ArchiveId": "NkbByEejwEggmBz2fTHgJrg0XBoDfjP4q6iu87-TjhqG6eGoOY9Z8i1_AUyUsuhPAdTqLHy8pTl5nfCFJmDl2yEZONi5L26Omw12vcs01MNGntHEQL8MBfGlqrEXAMPLEArchiveId"
'   "Description": "My archive description",
'   "SNSTopic": "arn:aws:sns:us-west-2:111111111111:Glacier-ArchiveRetrieval-topic-Example",
'   "Tier" : "Bulk"
' }

' Use this online tool to generate the code from sample JSON: 
' Generate Code to Create JSON

Dim json As New ChilkatJsonObject
success = json.UpdateString("Type","archive-retrieval")
success = json.UpdateString("ArchiveId","ARCHIVE_ID")
success = json.UpdateString("Description","My archive description")
' Possible tiers are Bulk, Standard, and Expedited.
success = json.UpdateString("Tier","Bulk")
' The SNSTopic is optional.  If included, then notification is sent to the SNS topic when the job is complete.
' This example will omit the SNSTopic.

Dim sbRequestBody As New ChilkatStringBuilder
success = json.EmitSb(sbRequestBody)
Dim sbResponseBody As New ChilkatStringBuilder

' Start an archive retrieval in for the vault named "chilkat".
success = rest.FullRequestSb("POST","/AWS_ACCOUNT_ID/vaults/chilkat/jobs",sbRequestBody,sbResponseBody)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim respStatusCode As Long
respStatusCode = rest.ResponseStatusCode
If (respStatusCode >= 400) Then
    Debug.Print "Response Status Code = " & respStatusCode
    Debug.Print "Response Header:"
    Debug.Print rest.ResponseHeader
    Debug.Print "Response Body:"
    Debug.Print sbResponseBody.GetAsString()
    Exit Sub
End If

' Success is indicated by a 202 response status with an empty response body.
Debug.Print "response status code = " & respStatusCode

' If successful, the response header looks like this.
' The Location and x-amz-job-id are two items of information we may wish to save..

' HTTP/1.1 202 Accepted
' x-amzn-RequestId: AAABZpJrTyioDC_HsOmHae8EZp_uBSJr6cnGOLKp_XJCl-Q
' Date: Wed, 10 Feb 2017 12:00:00 GMT 
' Location: /111122223333/vaults/examplevault/jobs/HkF9p6o7yjhFx-K3CGl6fuSm6VzW9T7esGQfco8nUXVYwS0jlb5gq1JZ55yHgt5vP54ZShjoQzQVVh7vEXAMPLEjobID
' x-amz-job-id: HkF9p6o7yjhFx-K3CGl6fuSm6VzW9T7esGQfco8nUXVYwS0jlb5gq1JZ55yHgt5vP54ZShjoQzQVVh7vEXAMPLEjobID
' 

Dim jobId As String
jobId = rest.ResponseHdrByName("x-amz-job-id")
Debug.Print "x-amz-job-id = " & jobId

Dim location As String
location = rest.ResponseHdrByName("Location")
Debug.Print "Location = " & location