(Visual Basic 6.0) Get FTP Directory Listing Information

Visual Basic 6.0 example showing how to get information about files and subdirectories in the current remote FTP directory.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Connect and login to the FTP server.
Dim success As Long
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' The ListPattern property is our directory listing filter.
' The default value is "*", which includes everything.
Debug.Print ftp.ListPattern

' To get file and sub-directory information, simply
' loop from 0 to ftp.GetDirCount() - 1
Dim i As Long
Dim n As Long
n = ftp.GetDirCount()
If (n < 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

If (n > 0) Then
    For i = 0 To n - 1

        ' Display the filename
        Debug.Print ftp.GetFilename(i)

        ' Display the file size (in bytes)
        Debug.Print ftp.GetSize(i)

        ' Is this a sub-directory?
        If (ftp.GetIsDirectory(i) = 1) Then
            Debug.Print ".. this is a sub-directory"
        End If

        Debug.Print "--"
    Next
End If

Debug.Print "-----------------------------------"

' Only files and directories
' matching the ListPattern are returned.
ftp.ListPattern = "*.asp"
n = ftp.GetDirCount()
If (n < 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

If (n > 0) Then
    For i = 0 To n - 1

        ' Display the filename
        Debug.Print ftp.GetFilename(i)

        ' Display the file size (in bytes)
        Debug.Print ftp.GetSize(i)

        Debug.Print "--"
    Next
End If

success = ftp.Disconnect()