(Visual Basic 6.0) Get Last Modified Date/Time of Files in a Remote Directory

Gets the last-modified date/times of files in a remote FTP directory.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Username = "myLogin"
ftp.Password = "myPassword"
' Use explicit TLS
ftp.AuthTls = 1
ftp.Port = 21

' For debugging, turn on session logging so we can examine what is sent by the server.
ftp.KeepSessionLog = 1

' Connect and login to the FTP server.
Dim success As Long
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Iterate over .txt files.
ftp.ListPattern = "*.txt"
Dim n As Long
n = ftp.GetDirCount()
Debug.Print "n = " & n

Dim dt As CkDateTime
Dim i As Long
i = 0
Do While i < n
    ' Get the last-modified date/time as a CkDateTime object.
    Set dt = ftp.GetLastModDt(i)
    Debug.Print i & ": " & ftp.GetFilename(i) & ", " & dt.GetAsTimestamp(0)

    i = i + 1
Loop

' Show the session log so we can see the details of the FTP directory listing sent by the server.
' This tells us what information is available.  Some FTP servers provide better and more accurate information
' than others.

Debug.Print "---- Session Log ----"
Debug.Print ftp.SessionLog

success = ftp.Disconnect()