(Visual Basic 6.0) Get FTP File Permissions

Visual Basic 6.0 example showing how to retrieve file permissions (via FTP) for each file in a remote directory.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

' Set the various properties to establish the connection.
ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' If SSL/TLS is required..
' See http://www.cknotes.com/determining-ftp2-connection-settings/ 
' for more information.
ftp.AuthTls = 1
ftp.PassiveUseHostAddr = 1

' Connect to the FTP server:
Dim success As Long
success = ftp.ConnectOnly()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Authenticate with the FTP server.
success = ftp.LoginAfterConnectOnly()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' To get file permissions in UNIX format, disallow MSLD:
ftp.AllowMlsd = 0

' To get file and sub-directory information, simply
' loop from 0 to ftp.GetDirCount() - 1
Dim i As Long
i = 0
Dim n As Long
n = ftp.GetDirCount()
If (n < 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Show the type of permissions information that is available.
' The two most common types are "mlsd" and "unix".  See the
' online reference documentation for more information.
If (n > 0) Then
    Debug.Print "The permissions format is: " & ftp.GetPermType(0)
End If

Do While i < n

    ' Display the permissions and filename
    Debug.Print ftp.GetPermissions(i) & " " & ftp.GetFilename(i)

    i = i + 1
Loop

' Assuming MLSD was possible, let's see the file permissions in MLSD format:
ftp.AllowMlsd = 1

' Clear the directory cache so we're forced to re-fetch the directory listing:
ftp.ClearDirCache 

n = ftp.GetDirCount()
If (n < 0) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Show the type of permissions information that is available.
' The two most common types are "mlsd" and "unix".  See the
' online reference documentation for more information.
If (n > 0) Then
    Debug.Print "----"
    Debug.Print "The permissions format is: " & ftp.GetPermType(0)
End If

i = 0
Do While i < n

    ' Display the permissions and filename
    Debug.Print ftp.GetPermissions(i) & " " & ftp.GetFilename(i)

    i = i + 1
Loop

success = ftp.Disconnect()