(Visual Basic 6.0) Directory Existence Check

How to test if a directory exists on an FTP server.

A good way to check to see if a directory already exists is to try to "cd" to that remote directory by calling ChangeRemoteDir. If it succeeds, then the directory exists. If not, then it does not exist. An alternative method is to set the ListPattern = "*" and then iterate over the files/directories, looking for the directory.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ftp As New ChilkatFtp2

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Connect and login to the FTP server.
Dim success As Long
success = ftp.Connect()
If (success <> 1) Then
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

' Does the "temp" directory exist?
Dim dirExists As Long
dirExists = ftp.ChangeRemoteDir("/temp")
If (dirExists = 1) Then
    Debug.Print "Yes, the temp directory exists."
    '  Yes, it exists. Restore the current remote dir:
    success = ftp.ChangeRemoteDir("..")
    If (success <> 1) Then
        Debug.Print ftp.LastErrorText
        Exit Sub
    End If

End If

' Alternatively, you may set the ListPattern = "*" and 
'  look for the directory:
ftp.ListPattern = "*"

Dim i As Long
Dim n As Long
n = ftp.GetDirCount()
If (n < 0) Then
    ' Failed to get directory listing based on ListPattern
    Debug.Print ftp.LastErrorText
    Exit Sub
End If

If (n > 0) Then
    For i = 0 To n - 1
        Dim isDir As Long
        isDir = ftp.GetIsDirectory(i)
        If (isDir = 1) Then
            Dim fname As String
            fname = ftp.GetFilename(i)
            If (fname = "temp") Then
                Debug.Print "Found temp directory!"
                success = ftp.Disconnect()
                Exit Sub
            End If

        End If

    Next
End If

success = ftp.Disconnect()