Visual Basic 6.0

Firebase PATCH - Updating Data

See more Firebase Examples

Uses the PATCH method to update record with new information. The data used in this example is at Chilkat Firebase Pigs Database, and is shown here:

Visual Basic 6.0

Dim success As Long
success = 0

' Uses the PATCH method to update a Firebase record.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a JWT authentication token, if required, has been previously obtained.
' See Get Firebase Access Token from JSON Service Account Private Key for sample code.

' Load the previously obtained Firebase access token into a string.
Dim fac As New CkFileAccess
Dim accessToken As String
accessToken = fac.ReadEntireTextFile("qa_data/tokens/firebaseToken.txt","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

Dim rest As New ChilkatRest

' Make the initial connection (without sending a request yet).
' Once connected, any number of requests may be sent.  It is not necessary to explicitly
' call Connect before each request.  
success = rest.Connect("chilkat.firebaseio.com",443,1,1)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim authGoogle As New ChilkatAuthGoogle
authGoogle.AccessToken = accessToken
success = rest.SetAuthGoogle(authGoogle)

' Chilkat's sample data (pig-rescue data) is publicly readable at: https://chilkat.firebaseio.com/.json
' This data is publicly readable, but not writable.  You'll need to 
' run against your own database..

' We're going to update "Molly II" to "Molly III"
Dim pigNameUpdate As New ChilkatJsonObject
success = pigNameUpdate.AppendString("name","Molly III")

' The string content of the last arg passed is  {"name":"Molly III"} 
Dim jsonResponse As String
jsonResponse = rest.FullRequestString("PATCH","/pig-rescue/animal/-KI3bD-FU_Dake7sYOiP.json",pigNameUpdate.Emit())
If (rest.LastMethodSuccess <> 1) Then
    ' Something happened in the communications (either no request was sent, or no response was received.
    ' (The Chilkat REST API also has lower-level methods where an app can send the request in one call,
    ' and then receive the response in another call.)
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Check the response status code.   A 200 response status indicates success.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print rest.ResponseStatusText
    Debug.Print jsonResponse
    Debug.Print "Failed."
    Exit Sub
End If

' When successful, the response contains the data written.
Debug.Print jsonResponse
Debug.Print "Success."