Visual Basic 6.0 Requires Chilkat v11.0.0+

Firebase Receive Server-Sent Events (text/event-stream)

See more Firebase Examples

Demonstrates how to start receiving server-sent events and update your JSON database with each event. Visual Basic 6.0

Dim success As Long
success = 0

'  Demonstrates how to begin receiving server-sent events, and to update
'  your JSON database for each event.

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example assumes a JWT authentication token, if required, has been previously obtained.
'  See Get Firebase Access Token from JSON Service Account Private Key for sample code.

'  Load the previously obtained Firebase access token into a string.
Dim fac As New CkFileAccess
Dim accessToken As String
accessToken = fac.ReadEntireTextFile("qa_data/tokens/firebaseToken.txt","utf-8")
If (fac.LastMethodSuccess = 0) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

Dim rest As New ChilkatRest

'  Make the initial connection (without sending a request yet).
'  Once connected, any number of requests may be sent.  It is not necessary to explicitly
'  call Connect before each request.  
success = rest.Connect("chilkat.firebaseio.com",443,1,1)
If (success = 0) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim authGoogle As New ChilkatAuthGoogle
authGoogle.AccessToken = accessToken
success = rest.SetAuthGoogle(authGoogle)

success = rest.AddHeader("Accept","text/event-stream")
success = rest.AddHeader("Cache-Control","no-cache")

Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/.json")

'  A 307 redirect response is expected.
If (rest.ResponseStatusCode <> 307) Then
    Debug.Print "Unexpected response code: " & rest.ResponseStatusCode
    Debug.Print responseBody
    Debug.Print "Failed."
    Exit Sub
End If

'  Get the redirect URL
Dim urlStr As String
urlStr = rest.LastRedirectUrl
Dim url As New ChilkatUrl
success = url.ParseUrl(urlStr)

Debug.Print "redirect URL domain: " & url.Host
Debug.Print "redirect URL path: " & url.Path
Debug.Print "redirect URL query params: " & url.Query
Debug.Print "redirect URL path with query params: " & url.PathWithQueryParams

'  Our text/event-stream will be obtained from the redirect URL...
Dim rest2 As New ChilkatRest

success = rest2.Connect(url.Host,443,1,1)
If (success <> 1) Then
    Debug.Print rest2.LastErrorText
    Exit Sub
End If

success = rest2.AddHeader("Accept","text/event-stream")
success = rest2.AddHeader("Cache-Control","no-cache")

'  Add the redirect query params to the request
success = rest2.AddQueryParams(url.Query)

'  In our case, we don't actually need the auth query param,
'  so remove it.
success = rest2.RemoveQueryParam("auth")

'  Send the request.  (We are only sending the request here.
'  We are not yet getting the response because the response
'  will be a text/event-stream.)
success = rest2.SendReqNoBody("GET",url.Path)
If (success <> 1) Then
    Debug.Print rest2.LastErrorText
    Exit Sub
End If

'  Read the response header.  
'  We want to first get the response header to see if it's a successful
'  response status code.  If not, then the response will not be a text/event-stream
'  and we should read the response body normally.
Dim responseStatusCode As Long
responseStatusCode = rest2.ReadResponseHeader()
If (responseStatusCode < 0) Then
    Debug.Print rest2.LastErrorText
    Exit Sub
End If

'  If successful, a 200 response code is expected.
'  If the reponse code is not 200, then read the response body and fail..
If (responseStatusCode <> 200) Then
    Debug.Print "Response Code: " & responseStatusCode
    Debug.Print "Response Status Text: " & rest2.ResponseStatusText
    Debug.Print "Response Header: " & rest2.ResponseHeader
    responseBody = rest2.ReadRespBodyString()
    If (rest2.LastMethodSuccess = 1) Then
        Debug.Print "Error Response Body: " & responseBody
    End If

    Debug.Print "Failed."
    Exit Sub
End If

'  For this example, our JSON database will be empty at the beginning.
'  The incoming events (put and patch) will be applied to this database.
Dim jsonDb As New ChilkatJsonObject

'  Make sure to set the JSON path delimiter to "/".  The default is "." and this
'  is not compatible with Firebase paths.
jsonDb.DelimiterChar = "/"

'  At this point, we've received the response header.  Now it's time to begin
'  receiving the event stream.  We'll start a background thread to read the 
'  stream.  (Our main application (foreground) thread can cancel it at any time.)  
'  While receiving in the background thread, our foreground thread can read the stream
'  as it desires..
Dim eventStream As New ChilkatStream

'  This sse object will be used as a helper to parse the server-sent event stream.
Dim sse As New ChilkatServerSentEvent

Dim task As ChilkatTask
Set task = rest2.ReadRespBodyStreamAsync(eventStream,1)
success = task.Run()

'  For this example, we'll just read a few events, and then cancel the
'  async task.
Dim count As Long
count = 0
Do While (count < 3) And (task.Finished = 0)

    '  Get the next event, which is a series of text lines ending with
    '  a blank line. 
    '  Note: This method blocks the calling thread until a message arrives.
    '  a program might instead periodically check the availability of
    '  data via the stream's DataAvailable property, and then do the read.

    '  An alternative to writing a while loop to read the event stream
    '  would be to setup some sort of timer event in your program (using whatever timer functionality
    '  is provided in a programming language/environment), to periodically check the eventStream's
    '  DataAvailable property and consume the incoming event.
    Dim eventStr As String
    eventStr = eventStream.ReadUntilMatch(vbCrLf & vbCrLf)
    If (eventStream.LastMethodSuccess <> 1) Then
        Debug.Print eventStream.LastErrorText
        '  Force the loop to exit by setting the count to a high number.
        count = 99999
    Else
        Debug.Print "Event: [" & eventStr & "]"

        '  We have an event. Let's update our local copy of the JSON database.
        success = sse.LoadEvent(eventStr)
        If (success <> 1) Then
            Debug.Print "Failed to load sse event: " & eventStr
        Else
            '  Now we can easily access the event name and data, and apply it to our JSON database:
            success = jsonDb.FirebaseApplyEvent(sse.EventName,sse.Data)
            If (success <> 1) Then
                Debug.Print "Failed to apply event: " & sse.EventName & ": " & sse.Data
            Else
                Debug.Print "Successfully applied event: " & sse.EventName & ": " & sse.Data
            End If

        End If

    End If

    count = count + 1
Loop

'  Make sure the background task is cancelled if still running.
success = task.Cancel()

'  Examine the JSON database after applying events..
jsonDb.EmitCompact = 0
Debug.Print "----"
Debug.Print jsonDb.Emit()