(Visual Basic 6.0) Find Certificate on Smartcard Currenty in Reader

Finds the certificates on smartcards currently in readers.

Note: This example requires Chilkat v9.5.0.77 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This newer example is a much better way to get the certificate on a smartcard or USB token

' This example requires that we already know the name of the CSP (Cryptographic Service Provider) for the smartcard.
' It is often the "Microsoft Base Smart Card Crypto Provider".  You can see what CSP's are registered on your system with this code:

Dim csp As New ChilkatCsp
Dim st As New ChilkatStringTable

Dim success As Long
success = csp.GetProviders(st)
If (success = 0) Then
    Debug.Print csp.LastErrorText
    Exit Sub
End If

' Iterate over the CSP names..
Dim i As Long
i = 0
Dim numProviders As Long
numProviders = st.Count
Do While i < numProviders
    Debug.Print i & ": " & st.StringAt(i)
    i = i + 1
Loop

' --------------------------
' This newer example is a much better way to get the certificate on a smartcard or USB token

' We'll assume our smartcard is accessed through the "Microsoft Base Smart Card Crypto Provider"
' Also, we'll assume that the certificate has been installed into the default current user Windows
' certificate store by following the instructions provided by the smartcard vendor.
' (The certificate does not contain the private key.  The certificate should be installed in the
' Windows current user certificate store.  It will also be on the smartcard, and the associated private
' key is only on the smartcard.)
' 

' First open the Current User Certificate Store.  We'll need it soon..
Dim certStore As New ChilkatCertStore
success = certStore.OpenCurrentUserStore(1)
If (success = 0) Then
    Debug.Print certStore.LastErrorText
    Exit Sub
End If

' Create a Csp object and set the ProviderName equal to our desired CSP name.
' (setting the ProviderName selects the desired CSP.)
csp.ProviderName = "Microsoft Base Smart Card Crypto Provider"

' Iterate over the key containers managed by this CSP.
' These will be the key containers for the cards currently inserted into the reader(s).
' If only one smartcard reader exists, and a smartcard is inserted, there should be one
' key container.
Dim numContainers As Long
numContainers = csp.NumKeyContainers

Debug.Print "numContainers = " & numContainers

i = 0
Do While i < numContainers
    ' For each key container, get the key container name and then find the certificate
    ' in the Current User Certicate Store with the matching key container name.
    Dim keyContainerName As String
    keyContainerName = csp.NthKeyContainerName(i)

    Dim cert As ChilkatCert
    Set cert = certStore.FindCertByKeyContainer(keyContainerName)
    If (certStore.LastMethodSuccess = 1) Then
        Debug.Print "Certificate in reader: " & cert.SubjectCN

    End If

    i = i + 1
Loop