(Visual Basic 6.0) Get the Photos for a User

Demonstrates how to get the photos that the user has uploaded.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a previously obtained an access token
Dim oauth2 As New ChilkatOAuth2
oauth2.AccessToken = "FACEBOOK-ACCESS-TOKEN"

Dim rest As New ChilkatRest

' Connect to Facebook.
Dim success As Long
success = rest.Connect("graph.facebook.com",443,1,1)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthOAuth2(oauth2)

' Indicate that we only want the photos the user has personally uploaded.
success = rest.AddQueryParam("type","uploaded")

' We could limit the number of photos by setting a limit.
success = rest.AddQueryParam("limit","5")

' Gets the 1st page of photos. (Not the actual image data, but the information about each photo.)
' See https://developers.facebook.com/docs/graph-api/reference/user/photos/ for more information.
Dim responseJson As String
responseJson = rest.FullRequestNoBody("GET","/v2.7/me/photos")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim json As New ChilkatJsonObject
json.EmitCompact = 0
success = json.Load(responseJson)
Debug.Print json.Emit()

' A sample JSON response is shown below.  
' This is the code to parse the JSON response.

Dim dtime As New CkDateTime
Dim bLocalTime As Long
bLocalTime = 1

Dim dt As DtObj
Dim i As Long
i = 0
Dim numItems As Long
numItems = json.SizeOfArray("data")
Do While i < numItems
    json.I = i
    Debug.Print "--- " & i
    Dim name As String
    name = json.StringOf("data[i].name")
    If (json.LastMethodSuccess = 1) Then
        Debug.Print "name: " & name
    End If

    Debug.Print "id: " & json.StringOf("data[i].id")

    ' We can load the created_time into a CkDateTime...
    success = dtime.SetFromTimestamp(json.StringOf("data[i].created_time"))
    Set dt = dtime.GetDtObj(bLocalTime)
    Debug.Print dt.Month & "/" & dt.Day & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute

    i = i + 1
Loop

' We can get the paging information as follows:
Debug.Print "URL for next page: " & json.StringOf("paging.next")
Debug.Print "before cursor: " & json.StringOf("paging.cursors.before")
Debug.Print "after cursor: " & json.StringOf("paging.cursors.after")

' This is a sample JSON response:
' { 
'   "data": [
'     {
'       "created_time": "2016-09-29T20:46:18+0000",
'       "name": "Ignore my posts -- I'm doing some testing for Facebook related programming...",
'       "id": "10210199026347451"
'     },
'     { 
'       "created_time": "2016-09-19T02:00:42+0000",
'       "id": "10210091531240138"
'     },
'     { 
'       "created_time": "2016-09-19T02:00:42+0000",
'       "id": "10210091520620125"
'     },
'     { 
'       "created_time": "2016-09-19T01:59:46+0000",
'       "name": "I would've went for a swim had it not been for the sign",
'       "id": "10210091522299917"
'     },
'     { 
'       "created_time": "2016-09-12T00:37:35+0000",
'       "id": "10210023316834798"
'     }
'   ],
'   "paging": { 
'     "cursors": { 
'       "before": "MTAyMTAxOTkwMjYzNDc0NTEZD",
'       "after": "MTAyMTAwMjMzMTU4MzQ3OTgZD"
'     },
'     "next": "https:\/\/graph.facebook.com\/v2.7\/10224048320139890\/photos?type=uploaded&limit=5&after=MTAyMTAwMjMzMTU4MzQ3OTgZD"
'   }
' }
'