(Visual Basic 6.0) Facebook Upload Photo from Local File

Uploads a new photo with a caption from a local file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes Chilkat HTTP to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "/v2.7/me/photos"

' Use the previously obtained access token.
' Note: The publish_actions scope is required to upload a photo.
req.AddHeader "Authorization","Bearer FACEBOOK-ACCESS-TOKEN"

' Send an "Expect: 100-continue" header in the request.
' This causes the HTTP server to end a 100-continue response
' immediately after receiving the HTTP header.  The client
' (Chilkat) will receive this intermediate response, and if
' it's not an error response, it knows that the HTTP server will
' accept the data that is forthcoming.
' The alternative is to get an error response after trying to upload
' the entire contents of the files.
req.AddHeader "Expect","100-continue"

' Set a photo caption.
req.AddParam "caption","Here are some penguins!"

' Additional parameters can be added to the request by 
' calling AddParam once per parameter.  
' See https://developers.facebook.com/docs/graph-api/reference/user/photos
' for more information about other optional parameters.

' Indicate the local file to be uploaded.
Dim success As Long
success = req.AddFileForUpload("source","qa_data/jpg/penguins2.jpg")
If (success <> 1) Then
    Debug.Print req.LastErrorText
    Exit Sub
End If

' Upload the image file..
Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest("graph.facebook.com",443,1,req)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Examine the response body:
Dim responseJson As String
responseJson = resp.BodyStr
Debug.Print responseJson

' The response contains JSON, such as this:
' {"id":"10210224963435862","post_id":"10224048320139890_10210224963435862"}