Visual Basic 6.0

Download Photo to a File

See more Facebook Examples

Assuming we have the ID of a Photo, this example demonstrates how to download the photo image data to a file. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a previously obtained an access token
Dim oauth2 As New ChilkatOAuth2
oauth2.AccessToken = "FACEBOOK-ACCESS-TOKEN"

Dim rest As New ChilkatRest

' Connect to Facebook...
success = rest.Connect("graph.facebook.com",443,1,1)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthOAuth2(oauth2)

' Assumes we've already obtained a Photo ID.
Dim photoId As String
photoId = "10210199026347451"

Dim sbPath As New ChilkatStringBuilder
success = sbPath.Append("/v2.7/")
success = sbPath.Append(photoId)

' First we're going to get the photo informaton so we can get the URL of the image file data.
' Select the fields we want.
' See https://developers.facebook.com/docs/graph-api/reference/photo/
success = rest.AddQueryParam("fields","id,album,images")

Dim responseJson As String
responseJson = rest.FullRequestNoBody("GET",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim json As New ChilkatJsonObject
json.EmitCompact = 0
success = json.Load(responseJson)

' Show the JSON in human-readable format.
Debug.Print json.Emit()

' Get the image URL.
Dim imageUrl As String
imageUrl = json.StringOf("images[0].source")
Debug.Print "Downloading from " & imageUrl

Dim sbImageUrl As New ChilkatStringBuilder
success = sbImageUrl.Append(imageUrl)

' Build the output local file path.
Dim sbToPath As New ChilkatStringBuilder
success = sbToPath.Append("qa_output/fb")
success = sbToPath.Append(json.StringOf("id"))
Dim bCaseSensitive As Long
bCaseSensitive = 0
If (sbImageUrl.Contains(".jpg",bCaseSensitive) = 1) Then
    success = sbToPath.Append(".jpg")
Else
    success = sbToPath.Append(".png")
End If

Debug.Print "Downloading to " & sbToPath.GetAsString()

' Download using Chilkat HTTP.
Dim http As New ChilkatHttp
success = http.Download(imageUrl,sbToPath.GetAsString())
If (success <> 1) Then
    Debug.Print http.LastErrorText
Else
    Debug.Print "Downloaded."
End If