(Visual Basic 6.0) Extract TSTInfo from RFC3161 Timestamp Reply

See more HTTP Examples

Sends an RFC 3161 timestamp request to a TSA (Timestamp Authority) server and converts the timestamp reply to XML, and then extracts the TSTInfo from the XML and converts it to XML.

For more information, see https://www.ietf.org/rfc/rfc3161.txt

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' Note: Requires Chilkat v9.5.0.75 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First sha-256 hash the data that is to be timestamped.
' In this example, the data is the string "Hello World"
Dim success As Long
Dim crypt As New ChilkatCrypt2
crypt.HashAlgorithm = "sha256"
crypt.EncodingMode = "base64"
Dim base64Hash As String
base64Hash = crypt.HashFileENC("qa_data/hamlet.xml")

Dim http As New ChilkatHttp

Dim requestToken As New ChilkatBinData
Dim optionalPolicyOid As String
optionalPolicyOid = ""
Dim addNonce As Long
addNonce = 0
Dim requestTsaCert As Long
requestTsaCert = 1

' Create a time-stamp request token
success = http.CreateTimestampRequest("sha256",base64Hash,optionalPolicyOid,addNonce,requestTsaCert,requestToken)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Send the time-stamp request token to the TSA.
' This is the equivalent of the following CURL command:
' curl -H "Content-Type: application/timestamp-query" --data-binary '@file.tsq' http://timestamp.digicert.com > file.tsr
Dim tsaUrl As String
tsaUrl = "http://timestamp.digicert.com"
Dim resp As ChilkatHttpResponse
Set resp = http.PBinaryBd("POST",tsaUrl,requestToken,"application/timestamp-query",0,0)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Get the timestamp reply from the HTTP response object.
Dim timestampReply As New ChilkatBinData
success = resp.GetBodyBd(timestampReply)

' Convert the binary timestamp reply to XML
Dim asn As New ChilkatAsn
success = asn.LoadBd(timestampReply)
If (success = 0) Then
    Debug.Print asn.LastErrorText
    Exit Sub
End If

Dim xml As New ChilkatXml
success = xml.LoadXml(asn.AsnToXml())

' Extract the TSTInfo from the XML.
' The TSTInfo is this base64 encoded ASN.1 

' TSTInfo ::= SEQUENCE  {
'    version                      INTEGER  { v1(1) },
'    policy                       TSAPolicyId,
'    messageImprint               MessageImprint,
'      -- MUST have the same value as the similar field in
'      -- TimeStampReq
'    serialNumber                 INTEGER,
'     -- Time-Stamping users MUST be ready to accommodate integers
'     -- up to 160 bits.
'    genTime                      GeneralizedTime,
'    accuracy                     Accuracy                 OPTIONAL,
'    ordering                     BOOLEAN             DEFAULT FALSE,
'    nonce                        INTEGER                  OPTIONAL,
'      -- MUST be present if the similar field was present
'      -- in TimeStampReq.  In that case it MUST have the same value.
'    tsa                          [0] GeneralName          OPTIONAL,
'    extensions                   [1] IMPLICIT Extensions   OPTIONAL  }

Dim tstInfoBase64 As String
tstInfoBase64 = xml.GetChildContent("sequence[1]|contextSpecific|sequence|sequence|contextSpecific|octets")

Dim bdTstInfo As New ChilkatBinData
success = bdTstInfo.AppendEncoded(tstInfoBase64,"base64")

Dim asnTstInfo As New ChilkatAsn
success = asnTstInfo.LoadBd(bdTstInfo)
If (success = 0) Then
    Debug.Print asnTstInfo.LastErrorText
    Exit Sub
End If

Dim xmlTstInfo As New ChilkatXml
success = xmlTstInfo.LoadXml(asnTstInfo.AsnToXml())
Debug.Print xmlTstInfo.GetXml()

' Here's the TSTInfo XML:

' <?xml version="1.0" encoding="utf-8"?>
' <sequence>
'     <int>01</int>
'     <oid>2.16.840.1.114412.7.1</oid>
'     <sequence>
'         <sequence>
'             <oid>2.16.840.1.101.3.4.2.1</oid>
'             <null/>
'         </sequence>
'         <octets>4sRRyWOzC7EOic4fQ9+Op1pa10DbgoBGjBvkq09LZmE=</octets>
'     </sequence>
'     <int>00AD2C86E49872597B60F87D5C54BCFFAE</int>
'     <universal tag="24" constructed="0">MjAyMzAzMTYxMTQ5NTJa</universal>
' </sequence>

'    The genTime (GeneralizedTime) is contained in the final "universal" XML element and is 
'    in base64. It is the time at which the time-stamp token has been created by
'    the TSA. After decoding from base64, it is:
' 
'    The syntax is: YYYYMMDDhhmmss[.s...]Z
'    Example: 19990609001326.34352Z

Dim sbGenTime As New ChilkatStringBuilder
success = sbGenTime.DecodeAndAppend(xmlTstInfo.GetChildContent("universal"),"base64","utf-8")
Debug.Print sbGenTime.GetAsString()

' Result:
' 20230316115718Z