(Visual Basic 6.0) Encrypt File in Chunks using AES CBC

Demonstrates how to use the FirstChunk/LastChunk properties to encrypt a file chunk-by-chunk.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"

Dim fileToEncrypt As String
fileToEncrypt = "qa_data/hamlet.xml"
Dim facIn As New CkFileAccess
Dim success As Long
success = facIn.OpenForRead(fileToEncrypt)
If (success <> 1) Then
    Debug.Print "Failed to open file that is to be encrytped."
    Exit Sub
End If

Dim outputEncryptedFile As String
outputEncryptedFile = "qa_output/hamlet.enc"
Dim facOutEnc As New CkFileAccess
success = facOutEnc.OpenForWrite(outputEncryptedFile)
If (success <> 1) Then
    Debug.Print "Failed to encrypted output file."
    Exit Sub
End If

' Let's encrypt in 10000 byte chunks.
Dim chunkSize As Long
chunkSize = 10000
Dim numChunks As Long
numChunks = facIn.GetNumBlocks(chunkSize)

crypt.FirstChunk = 1
crypt.LastChunk = 0

Dim bd As New ChilkatBinData

Dim i As Long
i = 0
Do While i < numChunks
    i = i + 1
    If (i = numChunks) Then
        crypt.LastChunk = 1
    End If

    ' Read the next chunk from the file.
    ' The last chunk will be whatever amount remains in the file..
    success = bd.Clear()
    success = facIn.FileReadBd(chunkSize,bd)

    ' Encrypt.
    success = crypt.EncryptBd(bd)

    ' Write the encrypted chunk to the output file.
    success = facOutEnc.FileWriteBd(bd,0,0)

    crypt.FirstChunk = 0
Loop

' Make sure both FirstChunk and LastChunk are restored to 1 after
' encrypting or decrypting in chunks.  Otherwise subsequent encryptions/decryptions
' will produce unexpected results.
crypt.FirstChunk = 1
crypt.LastChunk = 1

facIn.FileClose 
facOutEnc.FileClose 

' Decrypt the encrypted output file in a single call using CBC mode:
Dim decryptedFile As String
decryptedFile = "qa_output/hamlet_dec.xml"
success = crypt.CkDecryptFile(outputEncryptedFile,decryptedFile)
' Assume success for the example..

' Compare the contents of the decrypted file with the original file:
Dim bSame As Long
bSame = facIn.FileContentsEqual(fileToEncrypt,decryptedFile)
Debug.Print "bSame = " & bSame