Visual Basic 6.0

Load .eml and Examine the Structure, Attachments, and Related Items

See more Email Object Examples

Demonstrates how to load examine the MIME structure of a .eml, and also examine the attachment and related item filenames, attached messages, and multipart/report and DSN information. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim emlPath As String
emlPath = "C:/AAWorkarea/beatrix/roesner.eml"

Dim mime As New ChilkatMime

success = mime.LoadMimeFile(emlPath)
If (success = 0) Then
    Debug.Print mime.LastErrorText
    Exit Sub
End If

Debug.Print "---- MIME structure ----"
Debug.Print mime.GetStructure("text")
Debug.Print "------------------------"

Dim email As New ChilkatEmail
success = email.LoadEml(emlPath)

' Was this a signed and/or encrypted email?
' If so, then loading the .eml automatically unwraps
' (i.e. verifies signatures and decrypts) and the resultant
' email is what existed prior to signing/encrypting.
Debug.Print "Email was Signed: " & email.ReceivedSigned
Debug.Print "Email was Encrypted: " & email.ReceivedEncrypted
If (email.ReceivedSigned = 1) Then
    Debug.Print "Signature(s) valid = " & email.SignaturesValid
End If

If (email.ReceivedEncrypted = 1) Then
    Debug.Print "Decrypted successfully = " & email.Decrypted
End If

Dim i As Long
i = 0
Dim numAttach As Long
numAttach = email.NumAttachments
Debug.Print "Number of attachments = " & numAttach

Do While i < numAttach
    Debug.Print "---- Attachment " & i

    ' Examine the filename (if any)
    Debug.Print "filename: " & email.GetAttachmentFilename(i)
    ' Examine the content-ID (if any)
    Debug.Print "Content-ID: " & email.GetAttachmentContentID(i)
    ' Examine the content-type
    Debug.Print "Content-Type: " & email.GetAttachmentContentType(i)
    ' Examine the content-disposition
    Debug.Print "Content-Disposition" & email.GetAttachmentHeader(i,"content-disposition")
    ' Examine the attachment size:
    Debug.Print "Size (in bytes) of the attachment: " & email.GetAttachmentSize(i)

    i = i + 1
Loop
Debug.Print "--"

' Now for the related items.

' Note: A MIME sub-part can potentially be both a related item AND an attachment.
' The typical case is when the item is contained under the multipart/related enclosure and 
' the item also has a "Content-Disposition" header indicating "attachment".
' The location within multipart/related makes it a "related item", yet the Content-Disposition can also make it semantically an attachment.
' Related items and attachments are not necessarily mutually exclusive.

Dim numRelated As Long
numRelated = email.NumRelatedItems
Debug.Print "Number of related items = " & numRelated
i = 0
Do While i < numRelated
    Debug.Print "---- Related Item " & i

    ' Examine the filename (if any)
    Debug.Print "filename: " & email.GetRelatedFilename(i)
    ' Examine the content-ID (if any)
    Debug.Print "Content-ID: " & email.GetRelatedContentID(i)
    ' Examine the content-type
    Debug.Print "Content-Type: " & email.GetRelatedContentType(i)
    ' Examine the content-location (if any)
    Debug.Print "Content-Location" & email.GetRelatedContentLocation(i)

    i = i + 1
Loop

' The email could also have attached messages.
' An attached message is another email that was attached to this email.
Dim em As New ChilkatEmail
Dim numAttachedMessages As Long
numAttachedMessages = email.NumAttachedMessages
Debug.Print "Number of attached messages = " & numAttachedMessages
i = 0
Do While i < numAttachedMessages
    Debug.Print "---- Attached message " & i

    ' Examine the attached email
    success = email.GetAttachedEmail(i,em)
    Debug.Print "from: " & em.From
    Debug.Print "subject: " & em.Subject
    i = i + 1
Loop

' An email could also be a multipart/report email. 
' This is a DSN (Delivery Status Notification)
' The NumReports property indicates how many "reports" exist.
Dim numReports As Long
numReports = email.NumReports
Debug.Print "Number of reports = " & numReports
i = 0
Do While i < numReports
    Debug.Print "---- Report " & i
    ' Get the raw report data...
    Debug.Print email.GetReport(i)
    i = i + 1
Loop

' If the email is a multipart/report, then the information
' from the message/delivery-status part of the email can be retrieved:
If (email.IsMultipartReport() = 1) Then

    Debug.Print "--- Delivery Status Information:"
    Debug.Print "Status: " & email.GetDeliveryStatusInfo("Status")
    Debug.Print "Action: " & email.GetDeliveryStatusInfo("Action")
    Debug.Print "Reporting-MTA: " & email.GetDeliveryStatusInfo("Reporting-MTA")

    Dim jsonDsnInfo As New ChilkatJsonObject
    success = email.GetDsnInfo(jsonDsnInfo)
    jsonDsnInfo.EmitCompact = 0
    Debug.Print jsonDsnInfo.Emit()
End If