Visual Basic 6.0
Create HTML Email Reply

The goal of this example is to create a new HTML body where the new reply HTML is at the top, and the original HTML body is below.
The .eml files for this example are available at HTML Reply Email Samples (.eml)
Note: This is only one of a million ways to do it..
Chilkat Visual Basic 6.0 Downloads

Download Chilkat for Visual Basic 6.0
Visual Basic 6.0
Dim success As Long
success = 0

Dim email As New ChilkatEmail

' To create this example, I used Mozilla Thunderbird (with a GMail accont)
' to first send a simple HTML email to my chilkatsoft.com email address.  I then 
' used Thunderbird to reply with more HTML.
' I then saved both emails as .eml files.  These are available at
' http://chilkatdownload.com/example_data/htmlreplyemail.zip

' Load the .eml for the 1st email that was received. This is the original
' HTML email before the reply HTML is added.
success = email.LoadEml("qa_data/eml/receivedHtmlEmail.eml")
If (success <> 1) Then
    Debug.Print email.LastErrorText
    Exit Sub
End If

' If this email doesn't have an HTML body, then do something else...
' (that's for another example maybe?)
If (email.HasHtmlBody() = 0) Then
    Debug.Print "Email does not have an HTML body.."
    Exit Sub
End If

' Get the HTML body in a StringBuilder..
Dim sbHtml As New ChilkatStringBuilder
success = sbHtml.Append(email.GetHtmlBody())

' The HTML body contains this:
' <html><head>
' <meta http-equiv="Content-Type" content="text/html; charset=utf-8">
'   </head>
'   <body bgcolor="#FFFFFF" text="#000000">
'     <font face="Calibri"><br>
'       This is a test <font color="#3366ff"><i>HTML email</i></font>...<br>
'       <br>
'       <br>
'     </font>
'   </body>
' </html>

' Make sure the BODY tags are lowercase.
Dim numReplaced As Long
numReplaced = sbHtml.Replace("<BODY","<body")
numReplaced = sbHtml.Replace("</BODY","</body")

' Get the HTML within the "body" open/close tags
Dim sbBodyContent As New ChilkatStringBuilder
success = sbBodyContent.Append(sbHtml.GetAfterBetween("<body",">","</body>"))

' Replace what we just extracted with a marker..
numReplaced = sbHtml.Replace(sbBodyContent.GetAsString(),"TO_BE_UPDATED")

' Create a template for the new body:
Dim sbTemplate As New ChilkatStringBuilder
Dim bCrlf As Long
bCrlf = 1
success = sbTemplate.AppendLine("REPLY_HTML_CONTENT",bCrlf)
success = sbTemplate.AppendLine("<br>",bCrlf)
success = sbTemplate.AppendLine("<div class=""moz-signature"">Best Regards,<br>",bCrlf)
success = sbTemplate.AppendLine("  John Smith<br>",bCrlf)
success = sbTemplate.AppendLine("  Chilkat Software, Inc.<br>",bCrlf)
success = sbTemplate.AppendLine("  <p>",bCrlf)
success = sbTemplate.AppendLine("    <a href=""https://twitter.com/chilkatsoft"">Follow Chilkat on",bCrlf)
success = sbTemplate.AppendLine("      Twitter</a>",bCrlf)
success = sbTemplate.AppendLine("  </p>",bCrlf)
success = sbTemplate.AppendLine("</div>",bCrlf)
success = sbTemplate.AppendLine("<div class=""moz-cite-prefix"">On 2/8/2017 4:25 PM, Chilkat Support",bCrlf)
success = sbTemplate.AppendLine("  wrote:<br>",bCrlf)
success = sbTemplate.AppendLine("</div>",bCrlf)
success = sbTemplate.AppendLine("<blockquote>",bCrlf)
success = sbTemplate.AppendLine("ORIGINAL_BODY_CONTENT",bCrlf)
success = sbTemplate.AppendLine("</blockquote>",bCrlf)
success = sbTemplate.AppendLine("<br>",bCrlf)

' Replace the markers in the template with actual HTML.
' First our reply HTML:
Dim myHtmlReplyBody As String
myHtmlReplyBody = "This is my <font color=""#6600cc""><b>reply HTML</b></font><br>"
numReplaced = sbTemplate.Replace("REPLY_HTML_CONTENT",myHtmlReplyBody)

' Now for the original HTML body content:
numReplaced = sbTemplate.Replace("ORIGINAL_BODY_CONTENT",sbBodyContent.GetAsString())

' Insert into sbHtml:
numReplaced = sbHtml.Replace("TO_BE_UPDATED",sbTemplate.GetAsString())

' Use sbHtml as the new HTML body..
email.SetHtmlBody sbHtml.GetAsString()

' Examine the result HTML.
Debug.Print sbHtml.GetAsString()

' Save the email.
success = email.SaveEml("qa_output/emailWithUpdatedHtmlBody.eml")

' Note: To finish creating the reply email, modify the To/From/CC headers,
' the subject, etc.  You may also with to iterate over the headers (from 1 to NumHeaderFields)
' and selectively remove all except the particular headers you wish to keep.
' You should keep: MIME-Version, Content-Type, Message-ID.  Chilkat will automaticaly
' generate and replace the Message-ID at the time of sending.  You'll want to replace
' the Date header with the current date/time.
'