(Visual Basic 6.0) How to Generate an Elliptic Curve Shared Secret

Demonstrates how to generate an ECC (Elliptic Curve Cryptography) shared secret. Imagine a cilent has one ECC private key, the server has another. A shared secret is computed by each side providing it's public key to the other. The private keys are kept private.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example includes both client-side and server-side code.
' Each code segment is marked as client-side or server-side.
' Imagine these segments are running on separate computers...

Dim success As Long

' -----------------------------------------------------------------
' (Client-Side) Generate an ECC key, save the public part to a file.
' -----------------------------------------------------------------
Dim prngClient As New ChilkatPrng
Dim eccClient As New ChilkatEcc
Dim privKeyClient As PrivateKey
Set privKeyClient = eccClient.GenEccKey("secp256r1",prngClient)
If (eccClient.LastMethodSuccess <> 1) Then
    Debug.Print eccClient.LastErrorText
    Exit Sub
End If

Dim pubKeyClient As PublicKey
Set pubKeyClient = privKeyClient.GetPublicKey()
success = pubKeyClient.SavePemFile(0,"qa_output/eccClientPub.pem")

' -----------------------------------------------------------------
' (Server-Side) Generate an ECC key, save the public part to a file.
' -----------------------------------------------------------------
Dim prngServer As New ChilkatPrng
Dim eccServer As New ChilkatEcc
Dim privKeyServer As PrivateKey
Set privKeyServer = eccServer.GenEccKey("secp256r1",prngServer)
If (eccServer.LastMethodSuccess <> 1) Then
    Debug.Print eccServer.LastErrorText
    Exit Sub
End If

Dim pubKeyServer As PublicKey
Set pubKeyServer = privKeyServer.GetPublicKey()
success = pubKeyServer.SavePemFile(0,"qa_output/eccServerPub.pem")

' -----------------------------------------------------------------
' (Client-Side) Generate the shared secret using our private key, and the other's public key.
' -----------------------------------------------------------------

' Imagine that the server sent the public key PEM to the client.
' (This is simulated by loading the server's public key from the file.
Dim pubKeyFromServer As New PublicKey
success = pubKeyFromServer.LoadFromFile("qa_output/eccServerPub.pem")
Dim sharedSecret1 As String
sharedSecret1 = eccClient.SharedSecretENC(privKeyClient,pubKeyFromServer,"base64")

' -----------------------------------------------------------------
' (Server-Side) Generate the shared secret using our private key, and the other's public key.
' -----------------------------------------------------------------

' Imagine that the client sent the public key PEM to the server.
' (This is simulated by loading the client's public key from the file.
Dim pubKeyFromClient As New PublicKey
success = pubKeyFromClient.LoadFromFile("qa_output/eccClientPub.pem")
Dim sharedSecret2 As String
sharedSecret2 = eccServer.SharedSecretENC(privKeyServer,pubKeyFromClient,"base64")

' ---------------------------------------------------------
' Examine the shared secrets.  They should be the same.
' Both sides now have a secret that only they know.
' ---------------------------------------------------------
Debug.Print sharedSecret1
Debug.Print sharedSecret2