Visual Basic 6.0

ECDSA Sign and Verify Data using Different Hash Algorithms

See more ECC Examples

Demonstrates how to create ECDSA signatures on data using different hash algorithms.

Note: This example requires Chilkat v9.5.0.85 or greater because the SignBd and VerifyBd methods were added in v9.5.0.85.

Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load an ECDSA private key to be used for signing.
Dim privKey As New PrivateKey
success = privKey.LoadEncryptedPemFile("qa_data/ecc/secp256r1-key-pkcs8-secret.pem","secret")
If (success = 0) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' Load some data to be signed.
Dim bd As New ChilkatBinData
success = bd.LoadFile("qa_data/hamlet.xml")
If (success = 0) Then
    Debug.Print "Failed to load file to be hashed."
    Exit Sub
End If

Dim ecdsa As New ChilkatEcc
Dim prng As New ChilkatPrng

' Sign the sha256 hash of the data.  Return the ECDSA signature in the base64 encoding.
Debug.Print "ECDSA signing the sha256 hash of the data..."
Dim sig As String
sig = ecdsa.SignBd(bd,"sha256","base64",privKey,prng)
Debug.Print "sig = " & sig

' Verify the signature against the original data.
' (We must use the same hash algorithm that was used when signing.)

' Load the public key that corresponds to the private key used for signing.
Dim pubKey As New PublicKey
success = pubKey.LoadFromFile("qa_data/ecc/secp256r1-pub.pem")
If (success = 0) Then
    Debug.Print pubKey.LastErrorText
    Exit Sub
End If

Dim ecc2 As New ChilkatEcc
Dim result As Long
result = ecc2.VerifyBd(bd,"sha256",sig,"base64",pubKey)
If (result <> 1) Then
    Debug.Print ecc2.LastErrorText
    Exit Sub
End If

Debug.Print "Verified!"

' ----------------------------------------------------------------------------------------
' Let's do the same thing, but with sha384 hashing...

Debug.Print "--------------------------------------------"
Debug.Print "ECDSA signing the sha384 hash of the data..."

sig = ecdsa.SignBd(bd,"sha384","base64",privKey,prng)
Debug.Print "sig = " & sig

result = ecc2.VerifyBd(bd,"sha384",sig,"base64",pubKey)
If (result <> 1) Then
    Debug.Print ecc2.LastErrorText
    Exit Sub
End If

Debug.Print "Verified!"