Visual Basic 6.0

ECDSA Sign Data and Verify Signature

See more ECC Examples

Demonstrates using the Elliptic Curve Digital Signature Algorithm to hash data and sign it. Also demonstrates how to verify the ECDSA signature. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' To create an ECDSA signature, the data first needs to be hashed.  Then the hash
' is signed.

' Use Chilkat Crypt2 to generate a hash for any of the following
' hash algorithms: SHA256, SHA384, SHA512, SHA1, MD5, MD2, HAVAL, RIPEMD128/160/256/320

Dim crypt As New ChilkatCrypt2
crypt.HashAlgorithm = "SHA256"
crypt.Charset = "utf-8"
crypt.EncodingMode = "base64"

' Hash a string.
Dim hash1 As String
hash1 = crypt.HashStringENC("The quick brown fox jumps over the lazy dog")
Debug.Print "hash1 = " & hash1

' Or hash a file..
Dim hash2 As String
hash2 = crypt.HashFileENC("qa_data/hamlet.xml")
Debug.Print "hash2 = " & hash2

' (The Crypt2 API provides many other ways to hash data..)

' -----------------------------------------------------------
' An ECDSA private key is used for signing.  The public key is for signature verification.
' Load our ECC private key.
' Our private key file contains this:

' 	// -----BEGIN PRIVATE KEY-----
' 	MIGHAgEAMBMGByqGSM49AgEGCCqGSM49AwEHBG0wawIBAQQg3J8q/24D1sEKGdP9
' 	72MGYElLGpw/a56Y3t6pfON3uhShRANCAATlSmoizyhAwoYZAOuFBATl07/1RR54
' 	a1Dzfm16grxJe666AGKR+bSs24hk7TEpaeCTvT8YOOM3l+xKFg7zq6Q9
' 	-----END PRIVATE KEY-----

Dim privKey As New PrivateKey
success = privKey.LoadPemFile("qa_data/ecc/secp256r1-key-pkcs8.pem")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' We'll need a PRNG source for random number generation.
' Use Chilkat's PRNG (for the Fortuna PRNG algorithm).
Dim prng As New ChilkatPrng

' Sign the hash..
Dim ecdsa As New ChilkatEcc
Dim ecdsaSigBase64 As String
ecdsaSigBase64 = ecdsa.SignHashENC(hash1,"base64",privKey,prng)
If (ecdsa.LastMethodSuccess <> 1) Then
    Debug.Print ecdsa.LastErrorText
    Exit Sub
End If

Debug.Print "ECDSA signature = " & ecdsaSigBase64

' -----------------------------------------------------------
' Now let's verify the signature using the public key.

Dim pubKey As New PublicKey
success = pubKey.LoadFromFile("qa_data/ecc/secp256r1-pubkey.pem")
If (success <> 1) Then
    Debug.Print pubKey.LastErrorText
    Exit Sub
End If

Dim result As Long
result = ecdsa.VerifyHashENC(hash1,ecdsaSigBase64,"base64",pubKey)
If (result = 1) Then
    Debug.Print "Signature is valid."
    Exit Sub
End If

If (result = 0) Then
    Debug.Print "Signature is invalid."
    Exit Sub
End If

If (result < 0) Then
    Debug.Print ecdsa.LastErrorText
    Debug.Print "The VerifyHashENC method call failed."
    Exit Sub
End If