(Visual Basic 6.0) ECDSA Sign Data and Get Raw R and S Values

Demonstrates getting the raw R and S value of an ECDSA signature.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' To create an ECDSA signature, the data first needs to be hashed.  Then the hash
' is signed.

Dim crypt As New ChilkatCrypt2
crypt.HashAlgorithm = "SHA256"
crypt.Charset = "utf-8"
crypt.EncodingMode = "base64"

' Hash a string.
Dim hash1 As String
hash1 = crypt.HashStringENC("The quick brown fox jumps over the lazy dog")
Debug.Print "hash1 = " & hash1

' -----------------------------------------------------------
' An ECDSA private key is used for signing.  The public key is for signature verification.
' Load our ECC private key.
' Our private key file contains this:

' 	// -----BEGIN PRIVATE KEY-----
' 	MIGHAgEAMBMGByqGSM49AgEGCCqGSM49AwEHBG0wawIBAQQg3J8q/24D1sEKGdP9
' 	72MGYElLGpw/a56Y3t6pfON3uhShRANCAATlSmoizyhAwoYZAOuFBATl07/1RR54
' 	a1Dzfm16grxJe666AGKR+bSs24hk7TEpaeCTvT8YOOM3l+xKFg7zq6Q9
' 	-----END PRIVATE KEY-----

Dim privKey As New PrivateKey
Dim success As Long
success = privKey.LoadPemFile("qa_data/ecc/secp256r1-key-pkcs8.pem")
If (success <> 1) Then
    Debug.Print privKey.LastErrorText
    Exit Sub
End If

' Sign the hash..
Dim prng As New ChilkatPrng
Dim ecdsa As New ChilkatEcc
Dim ecdsaSigBase64 As String
ecdsaSigBase64 = ecdsa.SignHashENC(hash1,"base64",privKey,prng)
If (ecdsa.LastMethodSuccess <> 1) Then
    Debug.Print ecdsa.LastErrorText
    Exit Sub
End If

' The ECDSA signature is ASN.1 that contains a sequence of 2 large integers (r and s)
' For example:
' SEQUENCE (2 elem)
'   INTEGER (255 bit) 792134D9B4AD82D5431ED03835A88E2596EB35E5B13054BD9B05A0069281ACC9
'   INTEGER (255 bit) 481E758CC1E3CBF825537EC3D9A2CA627E5FAD1137BBEA65DF38658DCB0A9ED5

Debug.Print "Base64 ECDSA signature = " & ecdsaSigBase64

' If the raw R and S values are needed, here's how to get them:
Dim asn As New ChilkatAsn
success = asn.LoadEncoded(ecdsaSigBase64,"base64")
If (success = 0) Then
    Debug.Print asn.LastErrorText
    Exit Sub
End If

' The R and X will be in hexidecimal in the XML.
Dim xml As New ChilkatXml
success = xml.LoadXml(asn.AsnToXml())
Debug.Print xml.GetXml()

' The XML looks like this:
' <sequence>
' <int>792134D9B4AD82D5431ED03835A88E2596EB35E5B13054BD9B05A0069281ACC9</int>
' <int>481E758CC1E3CBF825537EC3D9A2CA627E5FAD1137BBEA65DF38658DCB0A9ED5</int>
' </sequence>

' Copy raw R and S hex values into a Chilkat BinData object.
Dim bd As New ChilkatBinData
Dim r As String
r = xml.GetChildContent("int[0]")
Dim s As String
s = xml.GetChildContent("int[1]")
success = bd.AppendEncoded(r,"hex")
success = bd.AppendEncoded(s,"hex")

Debug.Print "Number of bytes in bd: " & bd.NumBytes