(Visual Basic 6.0) eBay -- Get Inventory Items

Retrieves up to 100 inventory items. If an eBay account has more than 100 inventory items, then the Nth page of inventory items can be retrieved, until there are no more pages. (The first page of records has a value of 0, the second page of records has a value of 1, etc.)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Use a previously obtained user token.  The token should look something like this:
' "v^1.1#i^1#r^0#p^3#I^3#f^0#t^H4sIAAAAAAAAAOVXa2wUVRTu9k ... 89xuCWYREAAA=="
Dim accessToken As String
accessToken = "EBAY_ACCESS_TOKEN"

Dim http As New ChilkatHttp

' This example uses the sandbox.  
' Change "api.sandbox.ebay.com" to "api.ebay.com" to use the production system.
Dim sbUrl As New ChilkatStringBuilder
success = sbUrl.Append("https://api.sandbox.ebay.com/sell/inventory/v1/inventory_item?limit=_LIMIT&offset=_OFFSET")
Dim numReplaced As Long
numReplaced = sbUrl.Replace("_LIMIT","100")
' The offset indicates the page number.  Offset 0 gets items 0-99 (if limit=100),
' Offset 1 gets items 100-199, etc.
numReplaced = sbUrl.Replace("_OFFSET","0")

' Add our access token to the request, which is a header
' having the following format:
' Authorization: Bearer <userAccessToken>
Dim sbAuth As New ChilkatStringBuilder
success = sbAuth.Append("Bearer ")
success = sbAuth.Append(accessToken)
http.SetRequestHeader "Authorization",sbAuth.GetAsString()

http.Accept = "application/json"
http.AllowGzip = 1

Dim strJson As String
strJson = http.QuickGetStr(sbUrl.GetAsString())
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' The response should be JSON, even if an error.
Dim json As New ChilkatJsonObject
success = json.Load(strJson)
json.EmitCompact = 0

Debug.Print "Response status code = " & http.LastStatus

If (http.LastStatus <> 200) Then
    Debug.Print json.Emit()
    Debug.Print "Failed"
    Exit Sub
End If

' See the sample JSON response below..
Debug.Print json.Emit()

' To iterate over the inventory items..
Dim numItems As Long
numItems = json.SizeOfArray("inventoryItems")
Dim i As Long
i = 0
Dim j As Long
Do While i < numItems
    json.I = i
    Debug.Print i & ") sku: " & json.StringOf("inventoryItems[i].sku")
    Debug.Print "    title: " & json.StringOf("inventoryItems[i].product.title")

    If (json.HasMember("inventoryItems[i].product.aspects.Brand") = 1) Then
        Dim brands As ChilkatJsonArray
        Set brands = json.ArrayOf("inventoryItems[i].product.aspects.Brand")
        Dim numBrands As Long
        numBrands = brands.Size
        j = 0
        Do While j < numBrands
            Debug.Print "    brand: " & brands.StringAt(j)
            j = j + 1
        Loop
    End If

    If (json.HasMember("inventoryItems[i].product.aspects.Feature") = 1) Then
        Dim features As ChilkatJsonArray
        Set features = json.ArrayOf("inventoryItems[i].product.aspects.Feature")
        Dim numFeatures As Long
        numFeatures = features.Size
        j = 0
        Do While j < numFeatures
            Debug.Print "    feature: " & features.StringAt(j)
            j = j + 1
        Loop
    End If

    i = i + 1
Loop

' The output of the above loop:

' 0) sku: GP-Cam-01
'     title: GoPro Hero4 Helmet Cam
'     brand: GoPro
' 1) sku: AppleWatch
'     title: Test listing - do not bid or buy - awesome Apple watch test 2
'     feature: Water resistance
'     feature: GPS
' 
' 

' A sample JSON response with 2 inventory items.

' { 
'   "total": 2,
'   "size": 2,
'   "href": "/sell/inventory/v1/inventory_item?offset=0&limit=100",
'   "limit": 100,
'   "inventoryItems": [
'     { 
'       "sku": "GP-Cam-01",
'       "product": { 
'         "title": "GoPro Hero4 Helmet Cam",
'         "aspects": { 
'           "Brand": [
'             "GoPro"
'           ],
'           "Optical Zoom": [
'             "10x"
'           ],
'           "Type": [
'             "Helmet/Action"
'           ],
'           "Recording Definition": [
'             "High Definition"
'           ],
'           "Media Format": [
'             "Flash Drive (SSD)"
'           ],
'           "Storage Type": [
'             "Removable"
'           ]
'         },
'         "description": "New GoPro Hero4 Helmet Cam. Unopened box.",
'         "imageUrls": [
'           "http://i.ebayimg.com/images/i/182196556219-0-1/s-l1000.jpg",
'           "http://i.ebayimg.com/images/i/182196556219-0-1/s-l1001.jpg",
'           "http://i.ebayimg.com/images/i/182196556219-0-1/s-l1002.jpg"
'         ]
'       },
'       "condition": "NEW",
'       "availability": { 
'         "pickupAtLocationAvailability": [
'         ],
'         "shipToLocationAvailability": { 
'           "quantity": 50
'         }
'       }
'     },
'     { 
'       "sku": "AppleWatch",
'       "product": { 
'         "title": "Test listing - do not bid or buy - awesome Apple watch test 2",
'         "aspects": { 
'           "CPU": [
'             "Dual-Core Processor"
'           ],
'           "Feature": [
'             "Water resistance",
'             "GPS"
'           ]
'         },
'         "description": "Test listing - do not bid or buy\n Built-in GPS. Water resistance to 50 meters.1 A new lightning-fast dual-core processor. And a display that?s two times brighter than before. Full of features that help you stay active, motivated, and connected, Apple Watch Series 2 is designed for all the ways you move ",
'         "upc": [
'           "888462079525"
'         ],
'         "imageUrls": [
'           "http://store.storeimages.cdn-apple.com/4973/as-images.apple.com/is/image/AppleInc/aos/published/images/S/1/S1/42/S1-42-alu-silver-sport-white-grid?wid=332&hei=392&fmt=jpeg&qlt=95&op_sharpen=0&resMode=bicub&op_usm=0.5,0.5,0,0&iccEmbed=0&layer=comp&.v=1472247758975",
'           "http://store.storeimages.cdn-apple.com/4973/as-images.apple.com/is/image/AppleInc/aos/published/images/4/2/42/stainless/42-stainless-sport-white-grid?wid=332&hei=392&fmt=jpeg&qlt=95&op_sharpen=0&resMode=bicub&op_usm=0.5,0.5,0,0&iccEmbed=0&layer=comp&.v=1472247760390",
'           "http://store.storeimages.cdn-apple.com/4973/as-images.apple.com/is/image/AppleInc/aos/published/images/4/2/42/ceramic/42-ceramic-sport-cloud-grid?wid=332&hei=392&fmt=jpeg&qlt=95&op_sharpen=0&resMode=bicub&op_usm=0.5,0.5,0,0&iccEmbed=0&layer=comp&.v=1472247758007"
'         ]
'       },
'       "condition": "NEW",
'       "packageWeightAndSize": { 
'         "dimensions": { 
'           "width": 15.0,
'           "length": 10.0,
'           "height": 5.0,
'           "unit": "INCH"
'         },
'         "weight": { 
'           "value": 2.0,
'           "unit": "POUND"
'         }
'       },
'       "availability": { 
'         "pickupAtLocationAvailability": [
'         ],
'         "shipToLocationAvailability": { 
'           "quantity": 10
'         }
'       }
'     }
'   ]
' }
' 
' 
'