Visual Basic 6.0

Get eBay Application Token

See more eBay Examples

This example shows how to request an eBay Application token. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See the Ebay documentation about Access token types
' Also see the Ebay documentation about client credentials grant flow

Dim http As New ChilkatHttp

' If using the sandbox, the target endpoint will be:
' POST https://api.sandbox.ebay.com/identity/v1/oauth2/token

' If using the production (live) system, the target endpoint will be:
' POST https://api.ebay.com/identity/v1/oauth2/token

' The eBay client_id and client_secret needs to be sent
' in a Basic Authorization  request header, which has this format:
' Authorization: Basic <B64_encoded_oauth_credentials>

' Chilkat takes care of it.  You only need to set the Login = client_id,
' and password = client_secret, and indicate you want "Basic" HTTP Authorization.
http.Login = "EBAY_CLIENT_ID"
http.Password = "EBAY_CLIENT_SECRET"
http.BasicAuth = 1

' Let's do the following POST:

'   HTTP method:   POST
'   URL (Sandbox): https://api.sandbox.ebay.com/identity/v1/oauth2/token
' 
'   HTTP headers:
'     Content-Type = application/x-www-form-urlencoded
'     Authorization = Basic <B64-encoded-oauth-credentials>
' 
'   Request body (wrapped for readability):
'     grant_type=client_credentials&
'     redirect_uri=<RuName-value>&
'     scope=<SPACE separated list of scopes>
' 

' Create an HttpRequest object to hold the request params.
Dim req As New ChilkatHttpRequest
req.HttpVerb = "POST"
req.AddParam "grant_type","client_credentials"

' The scope query param indicates the access to be provided by the token.
' Multiple scopes can be specified by separating each with a SPACE char.
' See the Ebay OAuth scopes documentation

req.AddParam "scope","https://api.ebay.com/oauth/api_scope"

Dim endPoint As String
endPoint = "https://api.sandbox.ebay.com/identity/v1/oauth2/token"
req.ContentType = "application/x-www-form-urlencoded"

Dim resp As New ChilkatHttpResponse
success = http.HttpReq(endPoint,req,resp)
If (success = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' The response is JSON..
Dim json As New ChilkatJsonObject
success = json.Load(resp.BodyStr)
json.EmitCompact = 0

' If the response status code is not 200, then it failed.
Debug.Print "Response status code = " & resp.StatusCode
If (resp.StatusCode <> 200) Then
    Debug.Print json.Emit()
    Debug.Print "Failed."
    Exit Sub
End If

' We successfully retrieved an eBay access token.
' The actual access token string can be parsed from the JSON like this:
Dim accessToken As String
accessToken = json.StringOf("access_token")

' This application token is only valid for 7200 seconds (2 hours).  We'll want to refresh
' it before it expires.  (There is an online example for that..)
' For now, let's save the JSON to a file for our application to use.

' But before doing that, let's add to the JSON an expiration timestamp
' so we know when to refresh the token.
Dim dtExpire As New CkDateTime
success = dtExpire.SetFromCurrentSystemTime()
success = dtExpire.AddSeconds(json.IntOf("expires_in"))
success = json.AppendString("expire_time",dtExpire.GetAsTimestamp(0))

' Persist the JSON to a file.
Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/ebay.json",json.Emit(),"utf-8",0)
If (success <> 1) Then
    Debug.Print fac.LastErrorText
    Debug.Print "Failed to save eBay Application token to file."
    Exit Sub
End If

Debug.Print json.Emit()
Debug.Print "Success."

' The output of this example is:

' 	{ 
' 	  "access_token": "v^1.1#i^1#p^1#I^3#r^0# ... Ajp1BQhJDgAA",
' 	  "token_type": "Application Access Token",
' 	  "expires_in": 7200,
' 	  "refresh_token": "N/A",
' 	  "expire_time": "2017-04-16T14:44:20Z"
' 	}
' 
' 	Success.
'