(Visual Basic 6.0) Verify DKIM-Signature Headers in Downloaded Email

Downloads email from an IMAP server and verifies the DKIM-Signature header(s) in each email, if present.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim imap As New ChilkatImap

' Connect to an IMAP server, login, select mailbox..
' Use TLS 
imap.Ssl = 1
imap.Port = 993
Dim success As Long
success = imap.Connect("imap.someMailServer.com")
If (success = 1) Then
    success = imap.Login("myLogin","myPassword")
    If (success = 1) Then
        success = imap.SelectMailbox("Inbox")
    End If

End If

If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

Dim dkim As New ChilkatDkim

' Download a max of 10 emails and verify any DKIM-Signature headers
' that are present.

' Download emails by sequence numbers (not UIDs).
Dim bUid As Long
bUid = 0
Dim seqNum As Long
Dim j As Long
Dim n As Long
n = imap.NumMessages
If (n > 10) Then
    n = 10
End If

Dim json As New ChilkatJsonObject
json.EmitCompact = 0

' To verify DKIM-Signature headers, we need the exact unmodified MIME bytes of each email.
Dim mimeData As New ChilkatBinData
seqNum = 1
Do While seqNum <= n
    ' The FetchSingleBd method was introduced in v9.5.0.76
    success = imap.FetchSingleBd(seqNum,bUid,mimeData)
    If (success <> 1) Then
        Debug.Print imap.LastErrorText
        Exit Sub
    End If

    ' Get the number of DKIM-Signature headers.
    Dim numDkim As Long
    numDkim = dkim.NumDkimSigs(mimeData)

    ' Verify each..
    j = 0
    Do While j < numDkim
        Debug.Print "------ DKIM Signature " & j

        success = dkim.DkimVerify(j,mimeData)
        If (success <> 1) Then
            Debug.Print "Not valid."
        Else
            Debug.Print "valid."
        End If

        ' Show the additional information about the signature verification
        success = json.Load(dkim.VerifyInfo)
        Debug.Print json.Emit()

        ' The JSON contains information such as this:

        ' 	{
        ' 	  "domain": "amazonses.com",
        ' 	  "selector": "7v7vs6w47njt4pimodk5mmttbegzsi6n",
        ' 	  "publicKey": "MIGfMA0GCSqG...v2GvWPqGHz6uqeQIDAQAB",
        ' 	  "canonicalization": "relaxed/simple",
        ' 	  "algorithm": "rsa-sha256",
        ' 	  "signedHeaders": "Subject:From:To:Date:Mime-Version:Content-Type:References:Message-Id:Feedback-ID",
        ' 	  "verified": "yes"
        ' 	}

        j = j + 1
    Loop
    seqNum = seqNum + 1
Loop

success = imap.Disconnect()