(Visual Basic 6.0) Generate CSR with Uncommon Fields

See more CSR Examples

Demonstrates how to generate a new RSA key and a Certificate Signing Request (CSR) for this:

csr.common.name=Admin forInformation-MainShop
csr.serial.number=1-XYZ|2-2.0|3-999695
csr.organization.identifier=990099994100099
csr.organization.unit.name=9999910000
csr.organization.name=9999910000
csr.country.name=SA
csr.invoice.type=1100
csr.location.address=King Fahed Road
csr.industry.business.category=MainOffice

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First generate an RSA private key.
Dim rsa As New ChilkatRsa

' Generate a random 2048-bit RSA key.
Dim success As Long
success = rsa.GenerateKey(2048)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

' Get the private key
Dim privKey As PrivateKey
Set privKey = rsa.ExportPrivateKeyObj()

' Create the CSR object and set properties.
Dim csr As New ChilkatCsr

csr.CommonName = "Admin forInformation-MainShop"

' Country Name (2 letter code)
csr.Country = "SA"

' Organization Name (eg, company)
csr.Company = "9999910000"

' Organizational Unit Name (eg, secion/division)
csr.CompanyDivision = "9999910000"

' See https://www.alvestrand.no/objectid/2.5.4.html for OIDs for the following fields:

' csr.serial.number=1-XYZ|2-2.0|3-999695
' 2.5.4.5 - id-at-serialNumber 
success = csr.SetSubjectField("2.5.4.5","1-XYZ|2-2.0|3-999695","UTF8String")

' csr.organization.identifier=990099994100099
' 2.5.4.45 - id-at-uniqueIdentifier   Don't know if this is correct.
success = csr.SetSubjectField("2.5.4.45","1100","UTF8String")

' csr.invoice.type=1100
' Don't know what this OID would be...
success = csr.SetSubjectField("2.5.4.99","1100","UTF8String")

' csr.location.address=King Fahed Road
' 2.5.4.9 - id-at-streetAddress 
success = csr.SetSubjectField("2.5.4.9","King Fahed Road","UTF8String")

' csr.industry.business.category=MainOffice
' 2.5.4.15 - id-at-businessCategory 
success = csr.SetSubjectField("2.5.4.15","MainOffice","UTF8String")

' Create the CSR using the private key.
Dim pemStr As String
pemStr = csr.GenCsrPem(privKey)
If (csr.LastMethodSuccess <> 1) Then
    Debug.Print csr.LastErrorText

    Exit Sub
End If

' Save the private key and CSR to a files.
success = privKey.SavePkcs8EncryptedPemFile("password","qa_output/privKey1.pem")

Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_output/csr1.pem",pemStr,"utf-8",0)

' Show the CSR.
Debug.Print pemStr

' Sample output:
' The CSR PEM can be checked here:
' https://www.networking4all.com/en/support/tools/csr+check/
' Copy-and-paste the PEM into the online CSR Decoding / CSR Verification form

' 	-----BEGIN CERTIFICATE REQUEST-----
' 	MIIC6jCCAdICAQAwgaQxITAfBgNVBAMMGG15c3ViZG9tYWluLm15ZG9tYWluLmNv
' ...
' ...
' 	hJnYCvjzFz4O9VtT+JtP9ldRHWV3KpZ8ne3AjD+F
' 	-----END CERTIFICATE REQUEST-----