Visual Basic 6.0

Sign a Byte Array to Create a Detached Signature in a Byte Array

See more Digital Signatures Examples

Signs data contained in a byte array to produce a detached signature (also in a byte array). Also shows how to verify the signature. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim cert As New ChilkatCert
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success = 0) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

Dim fac As New CkFileAccess

Dim fileBytes() As Byte
fileBytes = fac.ReadEntireFile("qa_data/pdf/sample.pdf")
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

Dim crypt As New ChilkatCrypt2

success = crypt.SetSigningCert(cert)

' We can sign any type of file.
' The result is a detached signature (a signature that does not contain the data being signed).

Dim sigBytes() As Byte
sigBytes = crypt.SignBytes(fileBytes)
If (crypt.LastMethodSuccess <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

success = fac.WriteEntireFile("qa_output/sample.pdf.p7s",sigBytes)
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

' We can verify the detached signature like this
Dim verified As Long
verified = crypt.VerifyBytes(fileBytes,sigBytes)
If (crypt.LastMethodSuccess <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Verified = " & verified