(Visual Basic 6.0) Create .p7s using Smart Card or USB Token

Demonstrates how to create a .p7s using a certificate stored on a smart card or USB token.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

' Use a certificate on a smartcard or USB token.
Dim cert As New ChilkatCert

' Provide the smartcard PIN.
cert.SmartCardPin = "000000"

' Load the certificate on the smartcard currently in the reader (or on the USB token).
Dim success As Long
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Provide the certificate for signing.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Indicate that SHA-256 should be used.
crypt.HashAlgorithm = "sha256"

' Specify the signed attributes to be included.
Dim jsonSignedAttrs As New ChilkatJsonObject
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
success = jsonSignedAttrs.UpdateInt("messageDigest",1)
success = jsonSignedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

Dim inFile As String
inFile = "qa_data/xml/IT01234567890_11002.xml"
Dim sigFile As String
sigFile = "qa_output/IT01234567890_11002.xml.p7s"

' Create the .p7s, which is a signature file that does not embed the original data.
' (To create a signature file that also embeds the original data, call CreateP7M instead)
success = crypt.CreateP7S(inFile,sigFile)
If (success = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Success."