(Visual Basic 6.0) Sign JSON to Create CAdES P7S Bytes

Demonstrates how to sign JSON using a certificate + private key from a .p12/.pfx to create a CAdES P7S byte array.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

Dim cert As New ChilkatCert
Dim success As Long
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

' Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' The CadesEnabled property applies to all methods that create PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

Dim jsonSigningAttrs As New ChilkatJsonObject
success = jsonSigningAttrs.UpdateInt("contentType",1)
success = jsonSigningAttrs.UpdateInt("signingTime",1)
success = jsonSigningAttrs.UpdateInt("messageDigest",1)
success = jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = 0

' Create the CAdES-BES attached signature, which contains the original data.
crypt.Charset = "utf-8"
Dim cadesP7s() As Byte
cadesP7s = crypt.OpaqueSignString("{ ""abc"": 123}")
If (crypt.LastMethodSuccess = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

' Verify the signature and extract the original JSON:
Dim originalJson As String
originalJson = crypt.OpaqueVerifyString(cadesP7s)
If (crypt.LastMethodSuccess = 0) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Original JSON: " & originalJson

Debug.Print "Success!"