(Visual Basic 6.0) Azure Service Bus - Send Message to Topic

See more Azure Service Bus Examples

Example code showing how to send a message to an Azure Service Bus Topic.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' Note: Requires Chilkat v9.5.0.65 or greater.

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Make the initial connection.
' A single REST object, once connected, can be used for many Azure Service Bus REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim rest As New ChilkatRest
Dim bAutoReconnect As Long
bAutoReconnect = 1
Dim success As Long
success = rest.Connect("<yournamespace>.servicebus.windows.net",443,1,bAutoReconnect)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' Let's load a previously computed SAS token and use it.
' See Azure Shared Access Signature for an example to genenerate an Azure SAS token.
Dim sbToken As New ChilkatStringBuilder
success = sbToken.LoadFile("qa_data/tokens/serviceBusSas.txt","utf-8")

' Tell the REST object to use the Azure Shared Access Signature for authorization.
success = sbToken.Prepend("SharedAccessSignature ")
success = rest.AddHeader("Authorization",sbToken.GetAsString())

' ----------------------------------------------------------------------------------------------

' The code for sending to a topic is identical to the code sending to a queue.
' The only difference is that a topic name (or topic path) is used instead of queue name/path.

' Send to a topic named "gilaMonster";
Dim topicName As String
topicName = "gilaMonster"

' The HTTP request body contains the content of the message sent to the topic.
Dim sbRequestBody As New ChilkatStringBuilder
success = sbRequestBody.Append("Hello, I'm a gila monster!")

' Build the path..
Dim sbPath As New ChilkatStringBuilder
success = sbPath.Append("/")
success = sbPath.Append(topicName)
success = sbPath.Append("/messages")

' Add timeout and api-version query parameters.
success = rest.AddQueryParam("timeout","20")
success = rest.AddQueryParam("api-version","2013-08")

' Standard brokered message properties are placed in a BrokerProperties HTTP header. 
' The broker properties must be serialized in JSON format. To specify a TimeToLive value of 3600 seconds 
' and to add a message label "M1" to the message..
Dim json As New ChilkatJsonObject
success = json.AppendInt("TimeToLive",3600)
success = json.AppendString("Label","A123")
success = rest.AddHeader("BrokerProperties",json.Emit())

' To add custom properties, such as "Priority" and "Color"
success = rest.AddHeader("Priority","High")
success = rest.AddHeader("Color","pink")

Dim sbResponseBody As New ChilkatStringBuilder
success = rest.FullRequestSb("POST",sbPath.GetAsString(),sbRequestBody,sbResponseBody)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Debug.Print "Response Status Code = " & rest.ResponseStatusCode

' Check for a success response.
If (rest.ResponseStatusCode <> 201) Then
    Debug.Print rest.LastRequestStartLine
    Debug.Print rest.LastRequestHeader
    Debug.Print sbResponseBody.GetAsString()
    Debug.Print "Failed."
    Exit Sub
End If

' If successful, the 201 response will have no response body.

Debug.Print "Success."