(Visual Basic 6.0) Azure Service Bus - Delete Message

See more Azure Service Bus Examples

Deletes a message from a queue or subscription.

For more information, see https://docs.microsoft.com/en-us/rest/api/servicebus/unlock-message

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Make the initial connection.
' A single REST object, once connected, can be used for many Azure Service Bus REST API calls.
' The auto-reconnect indicates that if the already-established HTTPS connection is closed,
' then it will be automatically re-established as needed.
Dim rest As New ChilkatRest
Dim bAutoReconnect As Long
bAutoReconnect = 1
Dim success As Long
success = rest.Connect("<yournamespace>.servicebus.windows.net",443,1,bAutoReconnect)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Let's load a previously computed SAS token and use it.
' See Azure Shared Access Signature for an example to genenerate an Azure SAS token.
Dim sbToken As New ChilkatStringBuilder
success = sbToken.LoadFile("qa_data/tokens/serviceBusSas.txt","utf-8")

' Tell the REST object to use the Azure Shared Access Signature for authorization.
success = sbToken.Prepend("SharedAccessSignature ")
success = rest.AddHeader("Authorization",sbToken.GetAsString())

' ----------------------------------------------------------------------------------------------
' The code above this comment could be placed inside a function/subroutine within the application
' because the connection does not need to be made for every request.  Once the connection is made
' the app may send many requests..
' ----------------------------------------------------------------------------------------------

' To delete a message, we'll need either the SequenceNumber or MessageId.
' When the message was peek-locked, the SequenceNumber and MessageId of the locked message
' was returned in the HTTP response header named "BrokerProperties, which contained
' JSON such as the following:
' 
' 	{
' 	  "DeliveryCount": 1,
' 	  "EnqueuedSequenceNumber": 3000004,
' 	  "EnqueuedTimeUtc": "Wed, 07 Dec 2016 17:42:48 GMT",
' 	  "Label": "M3",
' 	  "LockToken": "6eeee205-e541-4cb6-95fb-4c81da5f6858",
' 	  "LockedUntilUtc": "Thu, 08 Dec 2016 00:57:32 GMT",
' 	  "MessageId": "e8028116d63c43f191577f2789b1cca7",
' 	  "SequenceNumber": 4,
' 	  "State": "Active",
' 	  "TimeToLive": 922337193600
' 	}
' 
' 
' The path for unlocking a message is constructed as follows, depending on
' whether it is a message on a queue or subscription:
' 
' (for a queue)
' /{queuePath}/messages/{messageId|sequenceNumber}/{lockToken}
' 
' (for a subscription)
' /{topicPath}/subscriptions/{subscriptionName}/messages/{messageId|sequenceNumber}/{lockToken}

' This example will build a path to delete a message contained in a subscription.
Dim topicName As String
topicName = "gilaMonster"
Dim subscriptionName As String
subscriptionName = "feedings"
Dim messageId As String
messageId = "e8028116d63c43f191577f2789b1cca7"
Dim lockToken As String
lockToken = "6eeee205-e541-4cb6-95fb-4c81da5f6858"

' Build the path..
Dim sbPath As New ChilkatStringBuilder
success = sbPath.Append("/{topicPath}/subscriptions/{subscriptionName}/messages/{messageId|sequenceNumber}/{lockToken}")
Dim numReplaced As Long
numReplaced = sbPath.Replace("{topicPath}",topicName)
numReplaced = sbPath.Replace("{subscriptionName}",subscriptionName)
numReplaced = sbPath.Replace("{messageId|sequenceNumber}",messageId)
numReplaced = sbPath.Replace("{lockToken}",lockToken)

' Add a timeout parameter.
success = rest.AddQueryParam("timeout","20")

' Use the DELETE HTTP verb to delete the message.
Dim sbResponseBody As New ChilkatStringBuilder
success = rest.FullRequestNoBodySb("DELETE",sbPath.GetAsString(),sbResponseBody)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Debug.Print "Response Status Code = " & rest.ResponseStatusCode

' Check for a success response.
If (rest.ResponseStatusCode <> 200) Then
    Debug.Print rest.LastRequestStartLine
    Debug.Print rest.LastRequestHeader
    Debug.Print sbResponseBody.GetAsString()
    Debug.Print "Failed."
    Exit Sub
End If

' If successful, the response body would be empty..
Debug.Print "Success."