(Visual Basic 6.0) Azure AD Service-to-service access token request

Send an Azure AD service-to-service token request to get an access token using a shared secret.

For more information, see https://docs.microsoft.com/en-us/azure/active-directory/develop/v1-oauth2-client-creds-grant-flow#service-to-service-access-token-request

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

' To see the exact HTTP request sent and the response, set the SessionLogFilename property:
http.SessionLogFilename = "qa_output/chilkatHttpLog.txt"

Dim req As New ChilkatHttpRequest

' Set the following request params:
' grant_type 	required 	Specifies the requested grant type. In a Client Credentials Grant flow, the value must be client_credentials.
' 
' client_id 	required 	Specifies the Azure AD client id of the calling web service. 
'     To find the calling application's client ID, in the Azure portal, click Azure Active Directory, click App registrations, click the application. 
'     The client_id is the Application ID
' 
' client_secret 	required 	Enter a key registered for the calling web service or daemon application in Azure AD. 
'     To create a key, in the Azure portal, click Azure Active Directory, click App registrations, click the application, click Settings, click Keys, and add a Key.
'     URL-encode this secret when providing it.
' 
' resource 	required 	Enter the App ID URI of the receiving web service. To find the App ID URI, in the Azure portal, click Azure Active Directory, 
'     click App registrations, click the service application, and then click Settings and Properties.

req.AddParam "grant_type","client_credentials"
req.AddParam "client_id","MY_CLIENT_ID"
req.AddParam "client_secret","MY_CLIENT_SECRET"
req.AddParam "resource","https://service.contoso.com/"

' The URL passed to PostUrlEncoded has this form:   https://login.microsoftonline.com/<tenant_id>/oauth2/token
Dim resp As ChilkatHttpResponse
Set resp = http.PostUrlEncoded("https://login.microsoftonline.com/<tenant_id>/oauth2/token",req)
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim respStatusCode As Long
respStatusCode = resp.StatusCode
Debug.Print "Response Status Code = " & respStatusCode

Dim json As New ChilkatJsonObject
json.EmitCompact = 0
success = json.Load(resp.BodyStr)
Debug.Print "Response JSON:"
Debug.Print json.Emit()

If (respStatusCode >= 400) Then
    Debug.Print "Response Header:"
    Debug.Print resp.Header
    Debug.Print "Failed."

    Exit Sub
End If

' Sample response:

' {
'   "token_type": "Bearer",
'   "expires_in": "3599",
'   "ext_expires_in": "3599",
'   "expires_on": "1570059833",
'   "not_before": "1570055933",
'   "resource": "https://adminchilkatsoft.onmicrosoft.com/eb1b8ced-76b7-4845-aec5-d3e91776e345",
'   "access_token": "eyJ0eXAiO ... pmgw"
' }

' To get the items from the JSON....
Dim token_type As String
token_type = json.StringOf("token_type")
Dim expires_in As String
expires_in = json.StringOf("expires_in")
Dim ext_expires_in As String
ext_expires_in = json.StringOf("ext_expires_in")
Dim expires_on As String
expires_on = json.StringOf("expires_on")
Dim not_before As String
not_before = json.StringOf("not_before")
Dim resource As String
resource = json.StringOf("resource")
Dim access_token As String
access_token = json.StringOf("access_token")