(Visual Basic 6.0) Auth0 Server-to-Server Access Token (Client Credentials flow)

Demonstrates how to obtain an Auth0 access token using client credentials (client_id and client_secret).

This is just a matter of duplicating this CURL command:

curl --request POST
  --url 'https://chilkat.auth0.com/oauth/token' \
  --header 'content-type: application/json' \
  --data '{"grant_type":"client_credentials","client_id": "xxxx","client_secret": "xxxx","audience": "https://api.example.com/geocoding/v1/"}'

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' We want to duplicate this curl command:
' 
' curl --request POST
'   --url 'https://chilkat.auth0.com/oauth/token' \
'   --header 'content-type: application/json' \
'   --data '{"grant_type":"client_credentials","client_id": "my_client_id","client_secret": "my_client_secret","audience": "https://api.example.com/geocoding/v1/"}'

' Build the JSON body of the request.
Dim json As New ChilkatJsonObject
success = json.UpdateString("grant_type","client_credentials")
success = json.UpdateString("client_id","AUTH0-CLIENT-ID")
success = json.UpdateString("client_secret","AUTH0-CLIENT-SECRET")
success = json.UpdateString("audience","https://api.example.com/geocoding/v1/")

' IMPORTANT: You would use your own url.  You would not use "chilkat.auth0.com".  
' Instead you would use "your_name.auth0.com"
Dim http As New ChilkatHttp
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson3("https://chilkat.auth0.com/oauth/token","application/json",json)
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' A 200 response status code indicates success.  In the success case, the response body
' contains the JSON access token, such as: 
' {
'   "access_token": "eyJz93a...k4laUWw",
'   "token_type":"Bearer",
'   "expires_in":86400
' }
' 

Debug.Print "response status code = " & resp.StatusCode

' The repsonse is JSON if successful and also JSON for errors.
Dim jsonResp As New ChilkatJsonObject
jsonResp.EmitCompact = 0
success = jsonResp.Load(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    ' The response body contains error information in JSON format.
    Debug.Print jsonResp.Emit()

    ' An example of an error response:
    ' 		{
    ' 		  "error": "access_denied",
    ' 		  "error_description": "Client is not authorized to access \"https://api.example.com/geocoding/v1/\". You might probably want to create a \"client-grant\" associated to this API. See: https://auth0.com/docs/api/v2#!/Client_Grants/post_client_grants"
    ' 		}
    Exit Sub
End If

Debug.Print "Success!"
Debug.Print jsonResp.Emit()

' A successful JSON response body looks like this:

' {
'   "access_token": "eyJz93a...k4laUWw",
'   "token_type":"Bearer",
'   "expires_in":86400
' }