(Visual Basic 6.0) Wait for Async Method to Complete

Demonstrates using the Wait method to wait for an asynchronous method to complete. This example will do an SFTP upload (over SSH) and will use the Async version of each method. Obviously, waiting for the async method to complete is the same as making a synchronous call, but an application wouldn't typically do this. An application might, for example, do other things as a background task is running, and then later wait for the task to complete.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' All Chilkat classes can be unlocked at once at the beginning of a program
' by calling UnlockBundle.  It requires a Bundle unlock code.
Dim chilkatGlob As New ChilkatGlobal
Dim success As Long
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> 1) Then
    Debug.Print chilkatGlob.LastErrorText
    Exit Sub
End If

Dim sftp As New ChilkatSFtp

' Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 15000
sftp.IdleTimeoutMs = 15000
Dim waitMaxMs As Long
waitMaxMs = 30000

' Connect to the SSH server.  
' The standard SSH port = 22
' The hostname may be a hostname or IP address.
Dim port As Long
port = 22
Dim hostname As String
hostname = "www.my-ssh-server.com"

Dim task As ChilkatTask
Set task = sftp.ConnectAsync(hostname,port)
If (sftp.LastMethodSuccess = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

' Start the background task.
success = task.Run()
If (Not success) Then
    Debug.Print task.LastErrorText
End If

' Wait for the connect task to finish.
' The 1/0 returned by Wait applies to the Wait method call, not the task.
success = task.Wait(waitMaxMs)
If (Not success Or (task.StatusInt <> 7) Or (task.TaskSuccess <> 1)) Then
    If (Not success) Then
        ' The task.LastErrorText applies to the Wait method call.
        Debug.Print task.LastErrorText
    Else
        ' The ResultErrorText applies to the underlying task method call (i.e. the Connect)
        Debug.Print task.Status
        Debug.Print task.ResultErrorText
    End If

    Exit Sub
End If

' Authenticate with the SSH server.  Chilkat SFTP supports
' both password-based authenication as well as public-key
' authentication.  This example uses password authenication.
Set task = sftp.AuthenticatePwAsync("myLogin","myPassword")
' To keep the example short, we'll skip handling failures.
' The failures would be handled in the same way as shown above.

success = task.Run()
success = task.Wait(waitMaxMs)

' After authenticating, the SFTP subsystem must be initialized:
Set task = sftp.InitializeSftpAsync()
success = task.Run()
success = task.Wait(waitMaxMs)

' Upload from the local file to the SSH server.
' Important -- the remote filepath is the 1st argument,
' the local filepath is the 2nd argument;
Dim remoteFilePath As String
remoteFilePath = "hamlet.xml"
Dim localFilePath As String
localFilePath = "c:/temp/hamlet.xml"

Set task = sftp.UploadFileByNameAsync(remoteFilePath,localFilePath)
If (sftp.LastMethodSuccess = 0) Then
    Debug.Print sftp.LastErrorText
    Exit Sub
End If

success = task.Run()
success = task.Wait(waitMaxMs)
If (Not success Or (task.StatusInt <> 7) Or (task.TaskSuccess <> 1)) Then
    If (Not success) Then
        ' The task.LastErrorText applies to the Wait method call.
        Debug.Print task.LastErrorText
    Else
        ' The ResultErrorText applies to the underlying task method call (i.e. the Connect)
        Debug.Print task.Status
        Debug.Print task.ResultErrorText
    End If

    Exit Sub
End If

Debug.Print "File uploaded."