(Visual Basic 6.0) Async Methods Returning an String

Demonstrates how to call an asynchronous method that returns a string. This example sends an HTTPS GET request to a URL and gets the HTML response.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New ChilkatHttp

Dim task As ChilkatTask
Set task = http.QuickGetStrAsync("https://www.chilkatsoft.com/helloWorld.html")
If (http.LastMethodSuccess = 0) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Start the background task.
Dim success As Long
success = task.Run()
If (Not success) Then
    Debug.Print task.LastErrorText

    Exit Sub
End If

' The application is now free to do anything else
' while the email is being sent.

' For this example, we'll simply sleep and periodically
' check to see if the HTTPS GET if finished.
Do While task.Finished <> 1
    ' Sleep 100 ms.
    task.SleepMs 100
Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task status: " & task.Status

    Exit Sub
End If

' The QuickGetStr method returns a string.  Therefore, after the task is finished,
' we can get the string result by calling GetResultString.  This is the return value had
' we called QuickGetStr synchronously.
Dim html As String
html = task.GetResultString()

Debug.Print html