Visual Basic 6.0

Getting the HTTP Response after an Asynchronous HTTP Request Completes

See more HTTP Examples

Some HTTP methods return an HTTP response object. This example demonstrates how to obtain the HTTP response object for such a method when calling asynchronously. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

success = 0

Dim http As New ChilkatHttp

' Call the async version of the QuickGetObj method to return a task object.
' The task object is loaded, but is in the Inert state -- meaning it is
' not yet scheduled to run on Chilkat's background thread pool.
Dim task As ChilkatTask
Set task = http.QuickGetObjAsync("https://stackexchange.com")
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

' Schedule the task for running on the thread pool.  This changes the task's state
' from Inert to Live.
success = task.Run()
If (success <> 1) Then
    Debug.Print task.LastErrorText

    Exit Sub
End If

' The application is now free to do anything else
' while the HTML page is being downloaded.

' For this example, we'll simply sleep and periodically
' check to see if the QuickGetObjAsync if finished.
Do While task.Finished <> 1

    ' Sleep 100 ms.
    task.SleepMs 100

Loop

' A finished task could be one that was canceled, aborted, or truly finished.  

' If the task was "canceled", it was canceled prior to actually starting.  This could
' happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
' background thread pool scheduler.  

' If the task was "aborted", it indicates that it was canceled while running in a background thread.  
' The ResultErrorText will likely indicate that the task was aborted.

' If the task "completed", then it ran to completion, but the actual success/failure of the method
' is determined by the result obtained via a GetResult* method.  (A "completed" task will
' have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
' been aborted or canceled:
If (task.StatusInt <> 7) Then
    Debug.Print "Task did not complete."
    Debug.Print "task status: " & task.Status

    Exit Sub
End If

' The synchronous call to QuickGetObj would return an HTTP response object.  To get this 
' response object for the async call, we instantiate a new/empty HTTP response object,
' and then load it from the completed task.
Dim resp As New ChilkatHttpResponse

success = resp.LoadTaskResult(task)
If (success <> 1) Then
    Debug.Print resp.LastErrorText

    Exit Sub
End If

' Now that we have the response, we can get all of the information:

Debug.Print "status code: " & resp.StatusCode
Debug.Print "response header: " & resp.Header

' ..