(Visual Basic 6.0) Create CAdES-T Signature using Aruba TSA Server (servizi.arubapec.it)

Demonstrates how to create a signature with an external timestamp (using the Aruba TSA Server) that certifies the time of signing.

Note: This example requires Chilkat v9.5.0.79 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim crypt As New ChilkatCrypt2

' This example will use a certificate + private key from a .pfx/.p12 file.
' On Windows systems, it is also possible to use certs on smartcards/usb tokens or certs pre-installed in the Windows registry.
Dim cert As New ChilkatCert

Dim pfxPath As String
pfxPath = "qa_data/pfx/myCertAndKey.p12"
Dim pfxPassword As String
pfxPassword = "test123"

Dim success As Long
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> 1) Then
    Debug.Print cert.LastErrorText
    Exit Sub
End If

success = crypt.SetSigningCert(cert)

' Use SHA-256 rather than the default of SHA-1
crypt.HashAlgorithm = "sha256"

' Create JSON that tells Chilkat what signing attributes to include:
Dim attrs As New ChilkatJsonObject
success = attrs.UpdateBool("contentType",1)
success = attrs.UpdateBool("signingTime",1)
success = attrs.UpdateBool("messageDigest",1)
success = attrs.UpdateBool("signingCertificateV2",1)

' A CAdES-T signature is one that includes a timestampToken created by an online TSA (time stamping authority).
' We must include the TSA's URL, as well as a few options to indicate what is desired.
' This example uses the Aruba TSA server, which requires a login/password for the HTTPS request.
success = attrs.UpdateBool("timestampToken.enabled",1)
success = attrs.UpdateString("timestampToken.tsaUrl","https://servizi.arubapec.it/tsa/ngrequest.php")

' The tsaUsername/tsaPassword feature was added in Chilkat v9.5.0.79.
' Make sure you are using a version of Chilkat that is no older than v9.5.0.79
success = attrs.UpdateString("timestampToken.tsaUsername","arubaTsaUsername")
success = attrs.UpdateString("timestampToken.tsaPassword","arubaTsaPassword")

success = attrs.UpdateBool("timestampToken.addNonce",0)
success = attrs.UpdateBool("timestampToken.requestTsaCert",1)
success = attrs.UpdateString("timestampToken.hashAlg","sha256")

crypt.SigningAttributes = attrs.Emit()

Dim inFile As String
inFile = "qa_data/json/sample.json"
Dim outFile As String
outFile = "qa_output/sample_cades_t.p7m"

' This creates the CAdES-T signature.  During the signature creation, it
' communicates with the TSA to get a timestampToken.
success = crypt.CreateP7M(inFile,outFile)
If (success <> 1) Then
    Debug.Print crypt.LastErrorText
    Exit Sub
End If

Debug.Print "Success."