(Visual Basic 6.0) Alabama Motor Fuel Excise Tax E-Filing SOAP XML POST (NewSubmission)

Demonstrates how to post a NewSubmission to the Alabama MFET (Motor Fuel Excise Tax) e-File.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

Dim success As Long

' Here is an example of an HTTP POST Request we'll be sending:

' POST /WebServices/MFET/ HTTP/1.1
' Content-Type: text/xml
' SOAPAction: NewSubmission
'  
' <soapenv:Envelope
'   xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
'   xmlns:tem="http://tempuri.org/"
'   xmlns:xsd="http://www.w3.org/2001/XMLSchema"
'   xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
'   <soapenv:Header/>
'   <soapenv:Body>
'     <tem:NewSubmission>
'       <tem:UserName>yourusername</tem:UserName>
'       <tem:Password>yourpassword</tem:Password>
'       <tem:File xsi:type="xsd:base64Binary">TRANSMISSION_XML_FILE_CONTENTS_AS_BASE64</tem:File>
'     </tem:NewSubmission>
'   </soapenv:Body>
' </soapenv:Envelope>

' In the above XML, the "TRANSMISSION_XML_FILE_CONTENTS_AS_BASE64" contains the base64 encoded
' string of the XML file that contains "<Transmission> ... </Transmission>"
' First let's load the transmission XML file and get the contents as base64.
Dim sbXml As New ChilkatStringBuilder
success = sbXml.LoadFile("qa_data/xml/AL_SR_999802_test.xml","utf-8")
If (success <> 1) Then
    Debug.Print "Failed to load XML file."
    Exit Sub
End If

success = sbXml.Encode("base64","utf-8")

' Build the XMl that will be the body of the HTTP request.
Dim xml As New ChilkatXml
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:tem","http://tempuri.org/")
success = xml.AddAttribute("xmlns:xsd","http://www.w3.org/2001/XMLSchema")
success = xml.AddAttribute("xmlns:xsi","http://www.w3.org/2001/XMLSchema-instance")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:UserName","yourusername"
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:Password","yourpassword"
success = xml.UpdateAttrAt("soapenv:Body|tem:NewSubmission|tem:File",1,"xsi:type","xsd:base64Binary")
xml.UpdateChildContent "soapenv:Body|tem:NewSubmission|tem:File",sbXml.GetAsString()

Dim http As New ChilkatHttp

http.SetRequestHeader "Content-Type","text/xml"
http.SetRequestHeader "SoapAction","NewSubmission"

Dim resp As ChilkatHttpResponse
Set resp = http.PostXml("https://mattest.alabama.gov/WebServices/MFET/",xml.GetXml(),"utf-8")
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Debug.Print "Response status code = " & resp.StatusCode
Debug.Print "Response body text:"
Debug.Print resp.BodyStr

' The response will look like this:

' <?xml version="1.0" encoding="utf-8" ?>
' <s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/">
'     <s:Body>
'         <NewSubmissionResponse xmlns="http://tempuri.org/">
'             <NewSubmissionResult i:type="a:base64Binary" xmlns:a="http://www.w3.org/2001/XMLSchema" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">BASE64_RESULT</NewSubmissionResult>
'         </NewSubmissionResponse>
'     </s:Body>
' </s:Envelope>

' We can get the base64 result like this:
Dim xmlResult As New ChilkatXml
success = xmlResult.LoadXml(resp.BodyStr)
Dim sbResult As New ChilkatStringBuilder
success = sbResult.Append(xmlResult.GetChildContent("s:Body|NewSubmissionResponse|NewSubmissionResult"))
success = sbResult.Decode("base64","utf-8")
Debug.Print "Decoded result:"
Debug.Print sbResult.GetAsString()

' A sample of a decoded error response:

' <?xml version="1.0" encoding="utf-8"?>
' <!--ADOR Acknowledgement 1-->
' <Transmission xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns="http://www.irs.gov/efile">
'   <Jurisdiction>ALABAMA</Jurisdiction>
'   <TransmissionId>2018-09-1019:14R000000001</TransmissionId>
'   <Timestamp>2018-09-10T19:14:12Z</Timestamp>
'   <Transmitter>
'     <ETIN>00000</ETIN>
'   </Transmitter>
'   <ProcessType>P</ProcessType>
'   <AgentIdentifier>ACK</AgentIdentifier>
'   <AcknowledgementID>0</AcknowledgementID>
'   <AcknowledgementTimeStamp>2018-09-11T21:16:34-05:00</AcknowledgementTimeStamp>
'   <Errors>
'     <Error>Process Type must be 'T' when submitted to Testing Web Service</Error>
'   </Errors>
' </Transmission>