Visual Basic 6.0

AI: Simple Stateless Streaming Response

See more AI Examples

Shows a simple stateless query and receives the response in streaming mode. Visual Basic 6.0

Dim success As Long
success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim ai As New ChilkatAi

' The provider can be "openai", "google", "claude", "deepseek", "xai", or "perplexity".
' Support for additional providers will be added in future versions of Chilkat.
ai.Provider = "openai"

' Use your provider's API key.
ai.ApiKey = "MY_API_KEY"

' Choose a model.
ai.Model = "gpt-4o"

' Indicate streaming mode is to be used.
ai.Streaming = 1

' Add a text input.
success = ai.InputAddText("Write a detailed story about a turtle who decides to run a bakery.  Describe the setting, the kinds of pastries, how the turtle feels, and include at least three paragraphs.")

' Ask the AI for text output.
success = ai.Ask("text")
If (success = 0) Then
    Debug.Print ai.LastErrorText
    Exit Sub
End If

Dim sbEventName As New ChilkatStringBuilder
Dim sbDelta As New ChilkatStringBuilder
Dim sbFullResponse As New ChilkatStringBuilder
Dim finished As Long
finished = 0
Dim abortFlag As Long
abortFlag = 0
Dim maxWaitMs As Long
maxWaitMs = 5000

Do While finished = 0

    Dim result As Long
    result = ai.PollAi(abortFlag)
    If (result = 1) Then
        ' We have output waiting.  It should be instantly available.  The maxWaitMs is just-in-case.
        success = ai.NextAiEvent(maxWaitMs,sbEventName,sbDelta)
        If (success = 0) Then
            Debug.Print ai.LastErrorText
            Exit Sub
        End If

        ' Some AI providers send many "empty" events.  Just ignore them.
        If (sbEventName.ContentsEqual("empty",1) = 0) Then
            ' Log the non-empty events.
            Debug.Print sbEventName.GetAsString()

            ' The delta contains the new output.  This could be emitted to a display or the terminal
            ' as real-time output.
            If (sbEventName.ContentsEqual("delta",1) = 1) Then
                Debug.Print sbDelta.GetAsString()

                ' Accumulate the delta's so we can show the full response later.
                success = sbFullResponse.AppendSb(sbDelta)
            Else
                ' A streaming AI response is always terminated by a single "null_terminator" event.
                finished = sbEventName.ContentsEqual("null_terminator",1)
            End If

        End If

    Else
        If (result = 0) Then
            ' Nothing is immediately available. Sleep for 1/10 of a second before polling again.
            ai.SleepMs 100
        Else
            ' Something failed..
            Debug.Print ai.LastErrorText
            finished = 1
        End If

    End If

Loop

' Show the accumulated (full) response.
Debug.Print "----"
Debug.Print sbFullResponse.GetAsString()

' -------------------------------------------------------------
' The response is in markdown format.
' Also see Markdown to HTML Conversion Examples.
' -------------------------------------------------------------