(PureBasic) Quickbooks OAuth2 in a Desktop App

See more QuickBooks Examples

Note: This example requires Chilkat v10.1.2 or greater.

Chilkat PureBasic Module Download Chilkat PureBasic Module

IncludeFile "CkOAuth2.pb"
IncludeFile "CkStringBuilder.pb"

Procedure ChilkatExample()

    ; To further clarify, see OAuth 2.0 Authorization Flow

    ; ------------------------------------------------------------------------------------------------
    ; IMPORTANT: You first need to define an App in the Quickbooks Developer Dashboard.
    ; See How to Create an App in QuickBooks Developer Dashboard
    ; ------------------------------------------------------------------------------------------------

    ; This example is for desktop applicatons (it is not for code that runs on a web server).
    ; You'll need to add a line (or a few lines of code) to popup a web browser that navigates to a URL.

    ; This is the way to initially obtain the OAuth2 access token.  Afterwards it can be 
    ; repeatedly refreshed without user interaction, as shown in this example: Refresh Quickbooks OAuth2 Access Token.

    oauth2.i = CkOAuth2::ckCreate()
    If oauth2.i = 0
        Debug "Failed to create object."
        ProcedureReturn
    EndIf

    ; QuickBooks OAuth2 allows for an "http://localhost:<portNumber>/" callback URL for sandbox testing,
    ; but not for production.

    ; In production, your applicaton must use your own public web server as an intermediate
    ; to receive and forward the redirect to localhost.
    ; See Using Your Web Server as an Intermediary for OAuth2 Redirect to localhost

    CkOAuth2::setCkAppCallbackUrl(oauth2, "https://yourwebserver.com/OAuth2.php")
    CkOAuth2::setCkListenPort(oauth2, 3017)

    CkOAuth2::setCkAuthorizationEndpoint(oauth2, "https://appcenter.intuit.com/connect/oauth2")
    CkOAuth2::setCkTokenEndpoint(oauth2, "https://oauth.platform.intuit.com/oauth2/v1/tokens/bearer")

    ; Replace these with actual values.
    CkOAuth2::setCkClientId(oauth2, "QUICKBOOKS-CLIENT-ID")
    CkOAuth2::setCkClientSecret(oauth2, "QUICKBOOKS-CLIENT-SECRET")
    CkOAuth2::setCkUseBasicAuth(oauth2, 1)
    CkOAuth2::setCkCodeChallenge(oauth2, 0)

    ; Indicate the desired access.  Possible scopes that can appear in the list are:
    ; com.intuit.quickbooks.accounting:  QuickBooks Online API
    ; com.intuit.quickbooks.payment:  QuickBooks Payments API
    ; openid:  OpenID Connect processing
    ; profile:  user's given and family names
    ; email:  user's email address
    ; phone:  user's phone number
    ; address:  user's physical address
    CkOAuth2::setCkScope(oauth2, "com.intuit.quickbooks.accounting")

    ; Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
    url.s = CkOAuth2::ckStartAuth(oauth2)
    If CkOAuth2::ckLastMethodSuccess(oauth2) <> 1
        Debug CkOAuth2::ckLastErrorText(oauth2)
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    Debug "url = " + url

    ; Launch the default browser on the system and navigate to the url.
    ; The LaunchBrowser method was added in Chilkat v10.1.2.
    success.i = CkOAuth2::ckLaunchBrowser(oauth2,url)
    If success = 0
        Debug CkOAuth2::ckLastErrorText(oauth2)
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    ; Wait for the user to approve or deny authorization in the browser.
    numMsWaited.i = 0
    While (numMsWaited < 90000) AND (CkOAuth2::ckAuthFlowState(oauth2) < 3)
        CkOAuth2::ckSleepMs(oauth2,100)
        numMsWaited = numMsWaited + 100
    Wend

    ; If the browser does not respond within the specified time, AuthFlowState will be:
    ; 
    ; 1: Waiting for Redirect – The OAuth2 background thread is waiting for the browser's redirect request.
    ; 2: Waiting for Final Response – The thread is awaiting the final access token response.
    ; In either case, cancel the background task initiated by StartAuth.

    If CkOAuth2::ckAuthFlowState(oauth2) < 3
        CkOAuth2::ckCancel(oauth2)
        Debug "No response from the browser!"
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    ; Check AuthFlowState to determine if authorization was granted, denied, or failed:
    ; 
    ; 3: Success – OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
    ; 4: Access Denied – OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
    ; 5: Failure – OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

    If CkOAuth2::ckAuthFlowState(oauth2) = 5
        Debug "OAuth2 failed to complete."
        Debug CkOAuth2::ckFailureInfo(oauth2)
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    If CkOAuth2::ckAuthFlowState(oauth2) = 4
        Debug "OAuth2 authorization was denied."
        Debug CkOAuth2::ckAccessTokenResponse(oauth2)
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    If CkOAuth2::ckAuthFlowState(oauth2) <> 3
        Debug "Unexpected AuthFlowState:" + Str(CkOAuth2::ckAuthFlowState(oauth2))
        CkOAuth2::ckDispose(oauth2)
        ProcedureReturn
    EndIf

    ; Save the full JSON access token response to a file.
    sbJson.i = CkStringBuilder::ckCreate()
    If sbJson.i = 0
        Debug "Failed to create object."
        ProcedureReturn
    EndIf

    CkStringBuilder::ckAppend(sbJson,CkOAuth2::ckAccessTokenResponse(oauth2))
    CkStringBuilder::ckWriteFile(sbJson,"qa_data/tokens/qb-access-token.json","utf-8",0)

    ; The full JSON received looks like this:
    ; {
    ;   "expires_in": 3600,
    ;   "x_refresh_token_expires_in": 8726400,
    ;   "refresh_token": "L011546037639r ... 3vR2DrbOmg0Sdagw",
    ;   "access_token": "eyJlbmMiOiJBMTI4Q0 ... oETJEMbeggg",
    ;   "token_type": "bearer"
    ; }

    Debug "OAuth2 authorization granted!"
    Debug "Access Token = " + CkOAuth2::ckAccessToken(oauth2)

    ; Get the realmId if needed...
    ; See About the QuickBooks REST API Realm ID, also known as Company ID
    realmId.s = CkOAuth2::ckGetRedirectRequestParam(oauth2,"realmId")
    If CkOAuth2::ckLastMethodSuccess(oauth2) = 1
        Debug "realmId: " + realmId
    Else
        Debug "No realmId was provided."
    EndIf



    CkOAuth2::ckDispose(oauth2)
    CkStringBuilder::ckDispose(sbJson)


    ProcedureReturn
EndProcedure