Lianja

Validate the at_hash Claim of an ID Token

See more JSON Web Token (JWT) Examples

Demonstrates how to hash an access token to compare it with the at_hash claim of an ID token. Lianja

llSuccess = .F.

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// This example uses a Google access_token + id_token that looks like this:

//  {
//   "access_token": "ya29.a0...0f",
//   "expires_in": 3599,
//   "scope": "openid https://www.googleapis.com/auth/userinfo.email",
//   "token_type": "Bearer",
//   "id_token": "eyJhb...o5nQ"
// }

loJsonToken = createobject("CkJsonObject")
llSuccess = loJsonToken.LoadFile("qa_data/tokens/google_sample_id_token.json")
if (llSuccess = .F.) then
    ? "Failed to load the JSON file..."
    release loJsonToken
    return
endif

// Use Chilkat's JWT API to examine the id_token..
loJwt = createobject("CkJwt")
lcIdToken = loJsonToken.StringOf("id_token")

// Extract the JOSE header..
lcJose = loJwt.GetHeader(lcIdToken)

loJsonHeader = createobject("CkJsonObject")
loJsonHeader.Load(lcJose)
loJsonHeader.EmitCompact = .F.
? loJsonHeader.Emit()

// The JOSE header looks like this:

// {
//   "alg": "RS256",
//   "kid": "e8799db06287515556213c80acbcfd022fb302a9",
//   "typ": "JWT"
// }

lcClaims = loJwt.GetPayload(lcIdToken)

loJsonClaims = createobject("CkJsonObject")
loJsonClaims.Load(lcClaims)
loJsonClaims.EmitCompact = .F.
? loJsonClaims.Emit()

// The claims look like this:

// {
//   "iss": "https://accounts.google.com",
//   "azp": "258999997753-5ni8lu5f15r7mno97d82f5lir9i9f6i1.apps.googleusercontent.com",
//   "aud": "258999997753-5ni8lu5f15r7mno97d82f5lir9i9f6i1.apps.googleusercontent.com",
//   "sub": "111787341816486547572",
//   "email": "somebody@gmail.com",
//   "email_verified": true,
//   "at_hash": "HYJZImlW3mUK-UfjRfXjKw",
//   "iat": 1615315968,
//   "exp": 1615319568
// }

// The at_hash is the Access Token hash value. Its value is the base64url encoding of the
// left-most half of the hash of the octets of the ASCII representation of the access_token value,
// where the hash algorithm used is the hash algorithm used in the alg Header Parameter of the
// ID Token's JOSE Header. For instance, if the alg is RS256, hash the access_token value with SHA-256,
// then take the left-most 128 bits and base64url encode them. The at_hash value is a case sensitive string.

lcToken_to_hash = loJsonToken.StringOf("access_token")
lcToken_hash_expected = loJsonClaims.StringOf("at_hash")

// Step 1. hashes the access token using SHA-256 (Google uses `RS256` as the ID Token `alg`).
loCrypt = createobject("CkCrypt2")
loBdHash = createobject("CkBinData")

loCrypt.HashAlgorithm = "sha256"
// This encoding mode must match the encoding mode passed in the 2nd arg to AppendEncoded.
// The encoding mode can be anything, as long as they are the same in both places.
loCrypt.EncodingMode = "hex"

llSuccess = loBdHash.AppendEncoded(loCrypt.HashStringENC(lcToken_to_hash),"hex")
lnSz = loBdHash.NumBytes

lcToken_hash_computed = loBdHash.GetEncodedChunk(0,lnSz / 2,"base64url")

// If the hashes are identical, then the access_token as issued for the given id_token.
? "token_hash_expected: " + lcToken_hash_expected
? "token_hash_computed: " + lcToken_hash_computed


release loJsonToken
release loJwt
release loJsonHeader
release loJsonClaims
release loCrypt
release loBdHash