(Lianja) Wait for Async Method to Complete

Demonstrates using the Wait method to wait for an asynchronous method to complete. This example will do an SFTP upload (over SSH) and will use the Async version of each method. Obviously, waiting for the async method to complete is the same as making a synchronous call, but an application wouldn't typically do this. An application might, for example, do other things as a background task is running, and then later wait for the task to complete.

Chilkat Lianja Extension Download Chilkat Lianja Extension

// All Chilkat classes can be unlocked at once at the beginning of a program
// by calling UnlockBundle.  It requires a Bundle unlock code.
loChilkatGlob = createobject("CkGlobal")
llSuccess = loChilkatGlob.UnlockBundle("Anything for 30-day trial.")
if (llSuccess <> .T.) then
    ? loChilkatGlob.LastErrorText
    release loChilkatGlob
    return
endif

loSftp = createobject("CkSFtp")

// Set some timeouts, in milliseconds:
loSftp.ConnectTimeoutMs = 15000
loSftp.IdleTimeoutMs = 15000
lnWaitMaxMs = 30000

// Connect to the SSH server.  
// The standard SSH port = 22
// The hostname may be a hostname or IP address.
lnPort = 22
lcHostname = "www.my-ssh-server.com"

loTask = loSftp.ConnectAsync(lcHostname,lnPort)
if (loSftp.LastMethodSuccess = .F.) then
    ? loSftp.LastErrorText
    release loChilkatGlob
    release loSftp
    return
endif

// Start the background task.
llSuccess = loTask.Run()
if (not llSuccess) then
    ? loTask.LastErrorText
endif

// Wait for the connect task to finish.
// The .T./.F. returned by Wait applies to the Wait method call, not the task.
llSuccess = loTask.Wait(lnWaitMaxMs)
if (not llSuccess or (loTask.StatusInt <> 7) or (loTask.TaskSuccess <> .T.)) then
    if (not llSuccess) then
        // The task.LastErrorText applies to the Wait method call.
        ? loTask.LastErrorText
    else
        // The ResultErrorText applies to the underlying task method call (i.e. the Connect)
        ? loTask.Status
        ? loTask.ResultErrorText
    endif

    release loTask
    release loChilkatGlob
    release loSftp
    return
endif

release loTask

// Authenticate with the SSH server.  Chilkat SFTP supports
// both password-based authenication as well as public-key
// authentication.  This example uses password authenication.
loTask = loSftp.AuthenticatePwAsync("myLogin","myPassword")
// To keep the example short, we'll skip handling failures.
// The failures would be handled in the same way as shown above.

llSuccess = loTask.Run()
llSuccess = loTask.Wait(lnWaitMaxMs)
release loTask

// After authenticating, the SFTP subsystem must be initialized:
loTask = loSftp.InitializeSftpAsync()
llSuccess = loTask.Run()
llSuccess = loTask.Wait(lnWaitMaxMs)
release loTask

// Upload from the local file to the SSH server.
// Important -- the remote filepath is the 1st argument,
// the local filepath is the 2nd argument;
lcRemoteFilePath = "hamlet.xml"
lcLocalFilePath = "c:/temp/hamlet.xml"

loTask = loSftp.UploadFileByNameAsync(lcRemoteFilePath,lcLocalFilePath)
if (loSftp.LastMethodSuccess = .F.) then
    ? loSftp.LastErrorText
    release loChilkatGlob
    release loSftp
    return
endif

llSuccess = loTask.Run()
llSuccess = loTask.Wait(lnWaitMaxMs)
if (not llSuccess or (loTask.StatusInt <> 7) or (loTask.TaskSuccess <> .T.)) then
    if (not llSuccess) then
        // The task.LastErrorText applies to the Wait method call.
        ? loTask.LastErrorText
    else
        // The ResultErrorText applies to the underlying task method call (i.e. the Connect)
        ? loTask.Status
        ? loTask.ResultErrorText
    endif

    release loTask
    release loChilkatGlob
    release loSftp
    return
endif

release loTask
? "File uploaded."


release loChilkatGlob
release loSftp