Visual FoxPro

Twinfield OAuth2 for Desktop App or Script

See more OAuth2 Examples

Demonstrates how to get a Twinfield OAuth2 access token from a desktop application or script. Visual FoxPro

LOCAL lnSuccess
LOCAL loOauth2
LOCAL lcUrl
LOCAL lnNumMsWaited
LOCAL loJson
LOCAL loFac

lnSuccess = 0

* For more information about the OAuth2, see OAuth 2.0 Authorization Flow

loOauth2 = CreateObject('Chilkat.OAuth2')

* This should be the port in the localhost callback URL for your app.  
* The callback URL would look like "http://localhost:3017/" if the port number is 3017.
loOauth2.ListenPort = 3017

loOauth2.AuthorizationEndpoint = "https://login.twinfield.com/auth/authentication/connect/authorize"
loOauth2.TokenEndpoint = "https://login.twinfield.com/auth/authentication/connect/token"

* Replace these with actual values.
loOauth2.ClientId = "CLIENT_ID"
loOauth2.ClientSecret = "CLIENT_SECRET"

loOauth2.Scope = "openid twf.user twf.organisation twf.organisationUser offline_access"

loOauth2.CodeChallenge = 1
loOauth2.CodeChallengeMethod = "S256"

* Twinfield requires that the request to exchange the authorization code for a token must be a GET.
* (In most cases, OAuth2 is implemented where the exchange for token HTTP request is a POST.)
* Note: The exchange-for-token happens within Chilkat in a background thread.  After the user interactively 
* accepts or denies authorization, the browser receives the response and redirects to localhost:<port>,
* where Chilkat is waiting on a background thread to receive the redirect, process it, and then send the HTTP request
* to exchange the code for a token.  This happens internally while your code below is waiting for the authorization..)
loOauth2.UncommonOptions = "EXCHANGE_CODE_FOR_TOKEN_USING_GET"

* Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
lcUrl = loOauth2.StartAuth()
IF (loOauth2.LastMethodSuccess <> 1) THEN
    ? loOauth2.LastErrorText
    RELEASE loOauth2
    CANCEL
ENDIF

? "url = " + lcUrl

* Launch the default browser on the system and navigate to the url.
* The LaunchBrowser method was added in Chilkat v10.1.2.
lnSuccess = loOauth2.LaunchBrowser(lcUrl)
IF (lnSuccess = 0) THEN
    ? loOauth2.LastErrorText
    RELEASE loOauth2
    CANCEL
ENDIF

* Wait for the user to approve or deny authorization in the browser.
lnNumMsWaited = 0
DO WHILE (lnNumMsWaited < 90000) AND (loOauth2.AuthFlowState < 3)
    loOauth2.SleepMs(100)
    lnNumMsWaited = lnNumMsWaited + 100
ENDDO

* If the browser does not respond within the specified time, AuthFlowState will be:
* 
* 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
* 2: Waiting for Final Response - The thread is awaiting the final access token response.
* In either case, cancel the background task initiated by StartAuth.

IF (loOauth2.AuthFlowState < 3) THEN
    loOauth2.Cancel()
    ? "No response from the browser!"
    RELEASE loOauth2
    CANCEL
ENDIF

* Check AuthFlowState to determine if authorization was granted, denied, or failed:
* 
* 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
* 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
* 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

IF (loOauth2.AuthFlowState = 5) THEN
    ? "OAuth2 failed to complete."
    ? loOauth2.FailureInfo
    RELEASE loOauth2
    CANCEL
ENDIF

IF (loOauth2.AuthFlowState = 4) THEN
    ? "OAuth2 authorization was denied."
    ? loOauth2.AccessTokenResponse
    RELEASE loOauth2
    CANCEL
ENDIF

IF (loOauth2.AuthFlowState <> 3) THEN
    ? "Unexpected AuthFlowState:" + STR(loOauth2.AuthFlowState)
    RELEASE loOauth2
    CANCEL
ENDIF

? "OAuth2 authorization granted!"
? "Access Token = " + loOauth2.AccessToken

* Get the full JSON response:
loJson = CreateObject('Chilkat.JsonObject')
loJson.Load(loOauth2.AccessTokenResponse)
loJson.EmitCompact = 0

* The JSON response looks like this:

? loJson.Emit()

* Save the JSON to a file for future requests.
loFac = CreateObject('Chilkat.FileAccess')
loFac.WriteEntireTextFile("qa_data/tokens/twinfield.json",loJson.Emit(),"utf-8",0)

RELEASE loOauth2
RELEASE loJson
RELEASE loFac