(Visual FoxPro) SSH Keyboard Authentication

Demonstrates how to implement keyboard authentication with an SSH server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

LOCAL loSsh
LOCAL lcHostname
LOCAL lnPort
LOCAL lnSuccess
LOCAL lcXmlResponse
LOCAL loXml

* This example assumes the Chilkat API to have been previously unlocked.
* See Global Unlock Sample for sample code.

* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Ssh')
loSsh = CreateObject('Chilkat.Ssh')

* Set some timeouts, in milliseconds:
loSsh.ConnectTimeoutMs = 5000
loSsh.IdleTimeoutMs = 15000

* Connect to the SSH server.  
* The standard SSH port = 22
* The hostname may be a hostname or IP address.
lcHostname = "sftp.example.com"
lnPort = 22
lnSuccess = loSsh.Connect(lcHostname,lnPort)
IF (lnSuccess <> 1) THEN
    ? loSsh.LastErrorText
    RELEASE loSsh
    CANCEL
ENDIF

* Begin keyboard authentication..
lcXmlResponse = loSsh.StartKeyboardAuth("myLogin")
IF (loSsh.LastMethodSuccess <> 1) THEN
    ? loSsh.LastErrorText
    RELEASE loSsh
    CANCEL
ENDIF

* If a user authentication banner was received, then your app
* may display it prior to prompting for the password.
? "UserAuthBanner: " + loSsh.UserAuthBanner

* For versions of Chilkat < 10.0.0, use CreateObject('Chilkat_9_5_0.Xml')
loXml = CreateObject('Chilkat.Xml')

lnSuccess = loXml.LoadXml(lcXmlResponse)
* Assume LoadXml succeeds for the example..
IF (loXml.HasChildWithTag("success") = 1) THEN
    ? "No password required, already authenticated."
    RELEASE loSsh
    RELEASE loXml
    CANCEL
ENDIF

IF (loXml.HasChildWithTag("error") = 1) THEN
    ? "Authentication already failed."
    RELEASE loSsh
    RELEASE loXml
    CANCEL
ENDIF

* See the online reference documentation for Chilkat SSH.
* The XML returned by StartKeyboardAuth will contain an infoRequest
* with one or more prompts that your application may choose to display.

* Call ContinueKeyboardAuth, passing in the whatever information is requires (such as the password).
* Typically, keyboard authentication requires one call to ContinueKeyboardAuth 
* using the password.  Theoretically, the SSH server could prompt for additional pieces
* of information.  The authentication is completed when the XML returned contains
* either a "success" or "error" child node.

* This example asumes only one call to ContinueKeyboardAuth is required.
lcXmlResponse = loSsh.ContinueKeyboardAuth("myPassword")
IF (loSsh.LastMethodSuccess <> 1) THEN
    ? loSsh.LastErrorText
    RELEASE loSsh
    RELEASE loXml
    CANCEL
ENDIF

lnSuccess = loXml.LoadXml(lcXmlResponse)
* Assume LoadXml succeeds for the example..
IF (loXml.HasChildWithTag("success") = 1) THEN
    ? "SSH Keyboard Authentication Successful!"
    RELEASE loSsh
    RELEASE loXml
    CANCEL
ENDIF

IF (loXml.HasChildWithTag("error") = 1) THEN
    ? "Authentication failed."
    RELEASE loSsh
    RELEASE loXml
    CANCEL
ENDIF

RELEASE loSsh
RELEASE loXml